blob: 5e920f0bcabd867d653d9bfed19ae1a904b6d9c5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Zile995 <stefan.zivkovic995@gmail.com>
pkgname=booster-um
pkgver=2.0.1
pkgrel=1
pkgdesc="Booster UKI Manager - A simple bash script to manage UKI files generated by booster and systemd-ukify"
url="https://github.com/Zile995/${pkgname}"
arch=('any')
license=('GPL-3.0-only')
install="${pkgname}.install"
backup=('etc/booster-um.yaml')
depends=('booster' 'go-yq' 'systemd' 'systemd-ukify' 'util-linux')
optdepends=('sbctl: Sign the UKI files'
'sbsigntools: Sign the UKI files with sbsign'
'efibootmgr: Manage EFI entries')
source=("${pkgname}-${pkgver}.zip::${url}/archive/${pkgver}.zip")
sha512sums=('87dd544ec425ab30cdfe01bf3316c2fea635fbd114ac5fd8e5ab7efa308a626800189d635d29d3a9c7fa9f85c314f36c71c4abe0bb79ce6fef9f7efe2532897a')
package() {
cd "${pkgname}-${pkgver}"
# Create config file
mkdir "${pkgdir}/etc/"
touch "${pkgdir}/etc/booster-um.yaml"
# Install the booster-um
install -Dm755 booster-um -t "${pkgdir}/usr/bin"
# Install the helper scripts
for script in scripts/*; do
install -Dm755 "$script" -t "${pkgdir}/usr/share/booster-um"
done
# Install the libaplm scripts
for libalpm_script in libalpm/scripts/*; do
install -Dm755 "$libalpm_script" -t "${pkgdir}/usr/share/libalpm/scripts"
done
# Install the libalpm hooks
for libalpm_hook in libalpm/hooks/*; do
install -Dm644 "$libalpm_hook" -t "${pkgdir}/usr/share/libalpm/hooks"
done
# Install completions
install -Dm644 "completions/zsh/_${pkgname}" -t "${pkgdir}/usr/share/zsh/site-functions/"
install -Dm644 "completions/bash/${pkgname}" -t "${pkgdir}/usr/share/bash-completion/completions"
}
|