blob: 8ab1be88f1715ca8d071288d0995044f23a26e13 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Jacob Mischka <jacob@mischka.me>
# Comaintainer: Pedro A. López-Valencia <https://aur.archlinux.org/user/vorbote>
pkgname=brave
pkgver=0.12.10
pkgrel=1
pkgdesc='Web browser that blocks ads and trackers by default.'
arch=('x86_64')
url='https://www.brave.com/'
license=('custom')
depends=('gtk2' 'nss' 'alsa-lib' 'gconf' 'libxtst' 'libxss' 'ttf-font')
makedepends=('npm' 'git')
provides=('brave-browser')
source=("https://github.com/brave/browser-laptop/archive/v"$pkgver"dev.tar.gz"
'brave.desktop')
sha512sums=('90591e6be488102302ab8cfd75b25b3eaa57a43c2582c284285ec7c1735281e8b831b6d7ae47804726126bf1c1f077fd321946a60890036bf2b492288880ae4d'
'337de1b406c89418fb27a49b1a9fa4cfef94eefbf2901bc60f5ddac0b9094924e940fcbcb233cbbeff2742e6b3c26cc6dbdb75cd29798eff8c8be92fce0df2e7')
build() {
cd "$srcdir"/browser-laptop-"$pkgver"dev
#cd "$srcdir"/browser-laptop-"$pkgver"dev-RC5
npm install
CHANNEL=dev npm run build-package
}
package() {
cd "$srcdir"/browser-laptop-"$pkgver"dev
#cd "$srcdir"/browser-laptop-"$pkgver"dev-RC5
install -dm0755 "$pkgdir"/usr/lib
cp -a --reflink=auto Brave-linux-x64 "$pkgdir"/usr/lib/brave
install -Dm0644 "$srcdir"/brave.desktop "$pkgdir"/usr/share/applications/brave.desktop
install -dm0755 "$pkgdir"/usr/bin
ln -s /usr/lib/brave/brave "$pkgdir"/usr/bin/brave
install -Dm0644 res/app.png "$pkgdir"/usr/share/pixmaps/brave.png
install -Dm0644 LICENSE.txt "$pkgdir"/usr/share/licenses/brave/MPL2
mv "$pkgdir"/usr/lib/brave/{LICENSE,LICENSES.chromium.html} "$pkgdir"/usr/share/licenses/brave/
}
|