blob: 032a2312cf1e1168366e78ed819e89a44712ed9a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
_reponame=brave-browser
pkgname=brave
pkgver=0.67.123
pkgrel=1
pkgdesc='A web browser that stops ads and trackers by default'
arch=('x86_64')
url='https://www.brave.com/download'
license=('custom')
depends=('gtk3' 'nss' 'alsa-lib' 'libxss' 'ttf-font' 'libva')
makedepends=('git' 'npm' 'python2' 'icu' 'glibc' 'gperf' 'java-runtime-headless')
optdepends=('cups: Printer support'
'pepper-flash: Adobe Flash support'
'libgnome-keyring: Enable GNOME keyring support')
source=("git+https://github.com/brave/brave-browser.git#tag=v${pkgver}"
'chromium-widevine.patch'
'chromium-skia-harmony.patch'
'chromium-vaapi-fix.patch'
'brave-vaapi-enable.patch'
'brave-launcher'
'brave.desktop')
sha256sums=('SKIP'
'd081f2ef8793544685aad35dea75a7e6264a2cb987ff3541e6377f4a3650a28b'
'771292942c0901092a402cc60ee883877a99fb804cb54d568c8c6c94565a48e1'
'333b1e0997ad8831906f66550efc73f51b8650ec3436a247d920b5d12e2169de'
'2b07eabd8b3d42456d2de44f6dca6cf2e98fa06fc9b91ac27966fca8295c5814'
'43f442d9ffacd69a1ca770b029083aaa544d48c052939a66e58a868d91ebde70'
'2191ba32800a423f37b7a667093e2bdef5762fe5111fee1d5067e66e26564488')
prepare() {
# Apply Brave patches
cd "${_reponame}"
patch -Np1 -i "${srcdir}/brave-vaapi-enable.patch"
# Hack to prioritize python2 in PATH
mkdir -p "${HOME}/bin"
ln -s /usr/bin/python2 "${HOME}/bin/python"
ln -s /usr/bin/python2-config "${HOME}/bin/python-config"
export PATH="${HOME}/bin:${PATH}"
# Prepare the environment
npm install
npm run init
# Apply Chromium patches
cd src/
patch -Np1 -i "${srcdir}/chromium-vaapi-fix.patch"
# Load Widevine CDM if available
patch -Np1 -i "${srcdir}/chromium-widevine.patch"
# https://crbug.com/skia/6663#c10
patch -Np0 -i "${srcdir}/chromium-skia-harmony.patch"
# Hacky patching
sed -e 's/enable_distro_version_check = true/enable_distro_version_check = false/g' -i chrome/installer/linux/BUILD.gn
}
build() {
cd "${_reponame}"
npm run build Release
}
package() {
install -d -m0755 "${pkgdir}/usr/lib/${pkgname}/"
# Copy necessary release files
cd "${_reponame}/src/out/Release"
cp -a --reflink=auto \
locales \
resources \
brave \
brave_*.pak \
chrome_*.pak \
icudtl.dat \
natives_blob.bin \
resources.pak \
v8_context_snapshot.bin \
"${pkgdir}/usr/lib/brave/"
cd "${srcdir}"
install -Dm0755 brave-launcher "${pkgdir}/usr/bin/${pkgname}"
install -Dm0644 -t "${pkgdir}/usr/share/applications/" "${pkgname}.desktop"
install -Dm0644 "${_reponame}/src/brave/app/theme/brave/product_logo_128.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -Dm0644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "${_reponame}/LICENSE"
install -Dm0644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "${_reponame}/src/brave/components/brave_sync/extension/brave-sync/node_modules/electron/dist/LICENSES.chromium.html"
}
# vim:set ts=4 sw=4 et:
|