blob: 413876dee84dd5766a137535847cbb3094a44483 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Contributor: Greg White <gwhite@kupulau.com>
# Maintainer: Greg White <gwhite@kupulau.com>
pkgname=brave-dev-bin
pkgver=1.33.95
pkgrel=1
pkgdesc='Web browser that blocks ads and trackers by default (dev binary release).'
arch=('x86_64')
url='https://brave.com/download-dev'
license=('MPL2')
depends=('gtk3' 'nss' 'alsa-lib' 'libxss' 'libgnome-keyring' 'ttf-font')
optdepends=('cups: Printer support'
'pepper-flash: Adobe Flash support'
'mesa: Hardware accelerated rendering'
'libglvnd: Support multiple different OpenGL drivers at any given time')
provides=("${pkgname}" 'brave-dev-browser')
conflicts=()
source=("https://github.com/brave/brave-browser/releases/download/v${pkgver}/brave-browser-dev_${pkgver}_amd64.deb"
'MPL2::https://raw.githubusercontent.com/brave/browser-laptop/master/LICENSE.txt'
"$pkgname.sh")
options=(!strip)
sha512sums=('ae2d13bb367dfb9284ddcda104bb2529f593f50f68bd924259bef8ce7929e0ff62fa45051a5938caedbdca70db2292c245d048a1bca1ac365207600dc3b9c81b'
'b8823586fead21247c8208bd842fb5cd32d4cb3ca2a02339ce2baf2c9cb938dfcb8eb7b24c95225ae625cd0ee59fbbd8293393f3ed1a4b45d13ba3f9f62a791f'
'a133f9ea4bd1f50f375a6039187fa886c380d77f1e47528f8350e1f9fbc6e1e7a1c8baaa40f6126c32ad3b9df57c456374564d1e7d7cd4c027b5ff2e96aa358e')
prepare() {
mkdir -p brave
tar xf data.tar.xz -C brave
# Delete unneeded cron job
rm -rf brave/opt/brave.com/brave-dev/cron
# Use our script to launch (allows overriding flags, sets up data dir)
sed -i "s/\/usr\/bin\/brave-browser-dev/\/usr\/bin\/brave-dev/g" brave/usr/share/applications/brave-browser-dev.desktop
}
package() {
cp -a --reflink=auto brave/opt "$pkgdir/opt"
cp -a --reflink=auto brave/usr "$pkgdir/usr"
install -Dm0755 "$pkgname.sh" "$pkgdir/usr/bin/brave-dev"
install -Dm0644 "brave/opt/brave.com/brave-dev/product_logo_128_dev.png" "$pkgdir/usr/share/pixmaps/brave-browser-dev.png"
install -Dm0664 -t "$pkgdir/usr/share/licenses/$pkgname" "brave/opt/brave.com/brave-dev/LICENSE"
chmod 4755 "$pkgdir/opt/brave.com/brave-dev/chrome-sandbox"
}
|