blob: 78fa4b2d7bff88c77c6a7d57d4273ea03d003b47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Maxim Baz <archlinux at maximbaz dot com>
_id=pjmbgaakjkbhpopmakjoedenlfdmcdgm
_name=browserpass-extension
pkgname=browserpass-chrome
pkgver=3.8.0
pkgrel=1
pkgdesc="Chrome extension for Browserpass, browser extension for zx2c4's pass (password manager)"
arch=('any')
url="https://github.com/browserpass/${_name}"
license=('ISC')
depends=('browserpass')
source=("${pkgname}-${pkgver}.crx::${url}/releases/download/${pkgver}/browserpass-github-${pkgver}.crx"
"${pkgname}-${pkgver}.crx.asc::${url}/releases/download/${pkgver}/browserpass-github-${pkgver}.crx.asc"
"${pkgname}-${pkgver}-LICENSE::https://raw.githubusercontent.com/browserpass/browserpass-extension/master/LICENSE")
noextract=("${pkgname}-${pkgver}.crx")
b2sums=('90af56defcee090fbe41984e922a1f3c7f57cc14ad9b8f2ad448d92ab41fa4eb70a987ba4c89de8f9c053a043f6bbbe912042d7dcce21651279f2b2727f68ec1'
'SKIP'
'9e54d91167393d3f3159c3598aa729434c1e7d8ef39083aa40ba6241c9b4b560c64bac1af43efa7be2dac72d8c35413b057b9f67eb41934e10bd8c733437e407')
validpgpkeys=('56C3E775E72B0C8B1C0C1BD0B5DB77409B11B601')
prepare() {
# Create extension json
cat << EOF > "${_id}".json
{
"external_crx": "/usr/lib/${pkgname}/${pkgname}-${pkgver}.crx",
"external_version": "${pkgver}"
}
EOF
}
package() {
install -Dm644 -t "${pkgdir}/opt/google/chrome/extensions/" "${_id}.json"
install -Dm644 -t "${pkgdir}/usr/lib/${pkgname}/" "${pkgname}-${pkgver}.crx"
# Install host json from browserpass package
install -dm755 "${pkgdir}/etc/opt/chrome/native-messaging-hosts/"
ln -sf "/usr/lib/browserpass/hosts/chromium/com.github.browserpass.native.json" "${pkgdir}/etc/opt/chrome/native-messaging-hosts/"
install -Dm644 "${pkgname}-${pkgver}-LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
# vim:set ts=4 sw=4 et:
|