PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109

# Maintainer: Vianney Bouchaud <aur dot vianney at bouchaud dot org>

pkgname=bruno
pkgdesc="Opensource API Client for Exploring and Testing APIs"
pkgver=3.0.2
pkgrel=1
arch=('x86_64')
url="https://www.usebruno.com/"
license=('MIT')
_electron=electron37
depends=(
    "${_electron}"
    'alsa-lib'
)
makedepends=(
    'nvm'
    'python-setuptools'
    'python'
)

source=(
   "${pkgname}-${pkgver}.tar.gz::https://github.com/usebruno/bruno/archive/v${pkgver}.tar.gz"
   com.usebruno.app.Bruno.desktop
)

sha256sums=(
    '0f926491e1c2ce52a63b62a81d0dd204f5becd0e19732e76b9c5673a68e138af'
    '7bad0d66e67fdaaf99d1b7b32ba2f119b7d6dba12ecfdb398c39ee3c81bbe051'
)

_ensure_local_nvm() {
  # lets be sure we are starting clean
  which nvm >/dev/null 2>&1 && nvm deactivate && nvm unload

  export NVM_DIR="${srcdir}/${pkgname}-${pkgver}/.nvm"
  # The init script returns 3 if version
  #   specified in ./.nvrc is not (yet) installed in $NVM_DIR
  #   but nvm itself still gets loaded ok
  source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
}

prepare() {
    _ensure_local_nvm
    cd "${pkgname}-${pkgver}"

    nvm install

    export HUSKY=0
    npm install --cache "${srcdir}/npm-cache" --include dev
    npm install node-addon-api --save-dev --cache "${srcdir}/npm-cache"
}

build() {
    _ensure_local_nvm
    export NODE_ENV=production
    export NODE_OPTIONS=--openssl-legacy-provider

    cd "${pkgname}-${pkgver}"

    npm run sandbox:bundle-libraries --workspace=packages/bruno-js

    npm run build --workspace=packages/bruno-common
    npm run build --workspace=packages/bruno-requests
    npm run build --workspace=packages/bruno-converters
    npm run build --workspace=packages/bruno-query
    npm run build --workspace=packages/bruno-graphql-docs
    npm run build --workspace=packages/bruno-schema-types
    npm run build --workspace=packages/bruno-filestore
    npm run build --workspace=packages/bruno-app

    rm -rf packages/bruno-electron/{out,web}
    mkdir -p packages/bruno-electron/web
    cp -r packages/bruno-app/dist/* packages/bruno-electron/web

    sed -i -e 's@/static/@static/@g' packages/bruno-electron/web/**.html
    sed -i -e 's@/static/font@../../static/font@g' packages/bruno-electron/web/static/css/**.**.css

    find packages/bruno-electron/web -name '*.map' -type f -delete

    electronDist="/usr/lib/${_electron}"
    electronVer="$(cat ${electronDist}/version)"

    npm run pack --workspace=packages/bruno-electron -- \
        --linux \
        --x64 \
        --config electron-builder-config.js \
        -c.electronDist=${electronDist} \
        -c.electronVersion=${electronVer}
}

package() {
    install -Dm0644 com.usebruno.app.Bruno.desktop -t "${pkgdir}/usr/share/applications/"

    cd "${pkgname}-${pkgver}"

    install -Dm0755 /dev/null "${pkgdir}/usr/bin/${pkgname}"
    cat >> "${pkgdir}/usr/bin/${pkgname}" <<EOD
#! /usr/bin/sh
ELECTRON_IS_DEV=0 exec ${_electron} /usr/lib/bruno "\$@"
EOD

    install -Dm0644 license.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
    install -d "${pkgdir}/usr/lib/${pkgname}/"
    npx --no asar e packages/bruno-electron/out/linux-unpacked/resources/app.asar "${pkgdir}/usr/lib/${pkgname}/"

    for i in 16 24 48 64 128 256 512 1024; do
        install -Dm644 "packages/bruno-electron/resources/icons/png/${i}x${i}.png" "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/com.usebruno.app.Bruno.png"
    done
}