blob: 258fd4af8843729558c4d97544afde4b3488a559 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Solomon Choina <shlomochoina at gmail dot com>
# Maintainer: Campbell Jones <arch at serebit dot com>
pkgname=budgie-desktop-git
pkgver=10.9.r0.g768972de
pkgrel=1
pkgdesc="A familiar, modern desktop environment - latest git"
arch=('x86_64' 'armv7h' 'aarch64')
url="https://github.com/BuddiesOfBudgie/budgie-desktop"
license=('GPL2' 'LGPL')
depends=('bluez' 'budgie-screensaver' 'budgie-control-center' 'budgie-session' 'gnome-themes-standard'
'libgee' 'libpeas' 'libwnck3' 'libxfce4windowing' 'magpie-wm' 'accountsservice' 'ibus' 'zenity')
makedepends=('git' 'gobject-introspection' 'intltool' 'meson' 'dart-sass' 'vala' 'gtk-doc')
optdepends=('budgie-desktop-view: Desktop icons'
'budgie-backgrounds: Default background set'
'network-manager-applet: Network management in the panel'
'power-profiles-daemon: Manage power and performance from the panel'
'switcheroo-control: Open apps with the secondary GPU')
provides=('budgie-desktop')
conflicts=('budgie-desktop')
source=("$pkgname"::'git+https://github.com/BuddiesOfBudgie/budgie-desktop.git'
"gvc"::"git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git"
"30_org.archlinux.budgie-desktop.gschema.override")
sha256sums=('SKIP'
'SKIP'
'500efe7bc76e6c6c383e5fed55503d3071646cc0ee71524860d6efcf229a920a')
pkgver() {
cd "$pkgname"
git describe --tags --long | sed 's/\([^-]*-g\)/r\1/; s/-/./g; s/^v//g'
}
prepare() {
cd "$pkgname"
git submodule init
git config submodule.gvc "$srcdir/gvc"
git submodule update
}
build() {
arch-meson "$pkgname" build
meson compile -C build
}
package() {
meson install -C build --destdir "$pkgdir"
install -Dm 644 30_org.archlinux.budgie-desktop.gschema.override -t "${pkgdir}/usr/share/glib-2.0/schemas"
}
|