summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3308b072154b88e406e3d87a87622322235796eb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
# $Id: PKGBUILD 243040 2015-08-05 00:47:34Z svenstaro $
# Maintainer: Philipp Mildenberger <philipp.mildenberger.. __AATT__ .. student.uibk.ac.at>
# Maintainer stable version: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Christoph Zeiler <archNOSPAM_at_moonblade.dot.org>

pkgbase='bullet-git'
pkgname=('bullet-git' 'bullet-docs-git')
pkgver=2.89.r21.gb57557c6c
pkgrel=1
pkgdesc="A 3D Collision Detection and Rigid Body Dynamics Library for games and animation"
arch=('i686' 'x86_64')
url="http://www.bulletphysics.com/Bullet/"
license=('custom:zlib')
makedepends=('cmake' 'doxygen' 'graphviz' 'ttf-dejavu' 'mesa' 'glu')
optdepends=('glu: for the example browser')
source=("git+https://github.com/bulletphysics/bullet3.git")
md5sums=('SKIP')

pkgver() {
  cd bullet3
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd bullet3

  [[ -d build ]] && rm -rf build
  mkdir build && cd build 

  cmake .. \
       -DCMAKE_INSTALL_PREFIX=/usr \
       -DBUILD_SHARED_LIBS=1 \
       -DINSTALL_LIBS=1 \
       -DINSTALL_EXTRA_LIBS=1 \
       -DCMAKE_BUILD_TYPE=Release

  make

  cd ..
  #sed -i 's/GENERATE_HTMLHELP.*//g' Doxyfile
  doxygen
}

package_bullet-git() {
  optdepends=('bullet-docs: documentation')
  provides=('bullet') 
  conflicts=('bullet')

  cd bullet3/build

  # install it
  make DESTDIR=${pkgdir} install

  # install license
  install -Dm644 ../LICENSE.txt ${pkgdir}/usr/share/licenses/${pkgbase}/LICENSE
}

package_bullet-docs-git() {
  pkgdesc="Documentation for bullet"
  provides=('bullet-docs') 
  conflicts=('bullet-docs')
  depends=()

  cd bullet3

  # install docs
  install -Dm644 docs/GPU_rigidbody_using_OpenCL.pdf ${pkgdir}/usr/share/doc/bullet/GPU_rigidbody_using_OpenCL.pdf
  install -Dm644 docs/Bullet_User_Manual.pdf ${pkgdir}/usr/share/doc/bullet/Bullet_User_Manual.pdf
  install -Dm644 docs/BulletQuickstart.pdf ${pkgdir}/usr/share/doc/bullet/BulletQuickstart.pdf
  cp -r html ${pkgdir}/usr/share/doc/bullet/html  
}
# vim: sw=2 ts=2 et: