PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75

# Maintainer: Donald Webster <fryfrog@gmail.com>
# Contributor: plenae
# Contributor: Spencer Muise <smuise@spencermuise.ca>

pkgname=calibre-web
pkgver=0.6.24
pkgrel=4
pkgdesc="Web app for browsing, reading and downloading eBooks stored in a Calibre database"
arch=('any')
url="https://github.com/janeczku/calibre-web"
license=('GPL3')
depends=(
  'file'
  'python'
  'python-apscheduler'
  'python-babel'
  'python-bleach'
  'python-chardet'
  'python-cryptography'
  'python-flask'
  'python-flask-babel'
  'python-flask-httpauth'
  'python-flask-limiter'
  'python-flask-principal'
  'python-flask-wtf'
  'python-lxml'
  'python-netifaces-plus'
  'python-pycountry'
  'python-pypdf'
  'python-magic'
  'python-pytz'
  'python-regex'
  'python-requests'
  'python-sqlalchemy'
  'python-tornado'
  'python-unidecode'
  'python-urllib3'
  'python-wand'
)
optdepends=(
  'python-jsonschema: kobo sync support'
)
makedepends=(
  'python-setuptools'
  'python-setuptools-scm'
)
provides=('calibre-web')
source=(
  "$pkgname-$pkgver.tar.gz::https://github.com/janeczku/calibre-web/archive/${pkgver}.tar.gz"
  'sqlalchemy.patch'
  'calibre-web.service'
  'calibre-web.sysusers'
  'calibre-web.tmpfiles'
)
sha256sums=('65d06505765e9a48c02451437e39afab3e7deb7bb13a705359ea271e32990cc8'
            'e109ad7b1778582f740b38148c4518cc556f3e032efa3b2e9b6ff2af19a70f31'
            '216c5443424aa9b38b71c53186d0369d2eacd2cb03d742e01c881ab7bac9ea2d'
            'b5d6c225761244b6c698af0279c9501bb9514e3e2a5151ca6e3212a4f5d0d76a'
            '82fae88cbed6d69e5a04586293de81bdc55994a4fe003178c39b5a35f2c87c1a')

# Remove once https://github.com/janeczku/calibre-web/commit/6cb1449ff31c8eb3b2b239517d79fbd9eb481447 is released.
prepare() {
  patch -d $pkgname-$pkgver -Np0 -i ../sqlalchemy.patch
}

package() {
  cd $pkgname-$pkgver
  install -d -m 755 "${pkgdir}/usr/lib/calibre-web"
  cp -a "${srcdir}/$pkgname-$pkgver"/* "${pkgdir}/usr/lib/calibre-web/"
  rm -rf "${pkgdir}/usr/lib/calibre-web/.git"

  install -D -m 644 "${srcdir}/calibre-web.service" "${pkgdir}/usr/lib/systemd/system/calibre-web.service"
  install -D -m 644 "${srcdir}/calibre-web.sysusers" "${pkgdir}/usr/lib/sysusers.d/calibre-web.conf"
  install -D -m 644 "${srcdir}/calibre-web.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/calibre-web.conf"
}