PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Yassine Oudjana <y.oudjana@protonmail.com>
# Contributor: Philip Goto <philip.goto@gmail.com>

pkgname=calls
pkgver=43.0
pkgrel=1
pkgdesc='Phone dialer and call handler'
arch=(x86_64 aarch64)
url='https://gitlab.gnome.org/GNOME/calls'
license=(GPL3)
depends=(
	callaudiod
	evolution-data-server
	feedbackd
	folks
	gom
	libhandy
	libpeas
	modemmanager
	sofia-sip
)
makedepends=(
	git
	gobject-introspection
	meson
	vala
)
source=(
	"git+${url}.git#tag=v${pkgver}"
	"git+https://gitlab.gnome.org/World/Phosh/libcall-ui.git"
)
b2sums=('SKIP'
        'SKIP')

prepare() {
	cd $pkgname

	git submodule init
	git submodule set-url subprojects/libcall-ui "../libcall-ui"
	git -c protocol.file.allow=always submodule update
}


build() {
	cd $pkgname
	arch-meson . _build
	ninja -C _build
}

package() {
	cd $pkgname

	DESTDIR="${pkgdir}" ninja install -C _build
}