blob: d36af191269ecde28ceedeabd052375ab2ffb98a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Maintainer: Carl Smedstad <carl.smedstad at protonmail dot com>
# Contributor: Yassine Oudjana <y.oudjana@protonmail.com>
# Contributor: Philip Goto <philip.goto@gmail.com>
pkgname=calls
pkgver=46.0
_commit=db9b771c19a22cf1ee46e1bce60c69a6c4c0e155
pkgrel=2
pkgdesc="Phone dialer and call handler"
arch=(x86_64 aarch64)
url="https://gitlab.gnome.org/GNOME/calls"
license=(GPL-3.0-or-later)
depends=(
callaudiod
dconf
evolution-data-server
feedbackd
folks
gcc-libs
glib2
glibc
gom
gstreamer
gtk3
hicolor-icon-theme
libgee
libhandy
libmm-glib
libpeas
libsecret
sofia-sip
)
makedepends=(
git
meson
python-docutils
python-packaging
vala
)
checkdepends=(
gst-plugins-bad
gst-plugins-base
gst-plugins-good
gst-plugins-ugly
)
source=(
"git+$url.git#commit=$_commit"
"git+https://gitlab.gnome.org/World/Phosh/libcall-ui.git"
"remove-failing-tests.patch"
)
sha256sums=(
'SKIP'
'SKIP'
'd4411f7eed3ac49ce78eb04e139ecc213ed02559ed8a8fb2337dca06969aab86'
)
_archive="$pkgname"
pkgver() {
cd "$_archive"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$_archive"
git submodule init
git config submodule.subprojects/libcall-ui.url "$srcdir/libcall-ui"
git -c protocol.file.allow=always submodule update
patch --forward --strip=1 --input="$srcdir/remove-failing-tests.patch"
}
build() {
cd "$_archive"
arch-meson . build
meson compile -C build
}
check() {
cd "$_archive"
meson test -C build --print-errorlogs
}
package() {
cd "$_archive"
meson install -C build --destdir "$pkgdir"
}
|