PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: uint2048_t

pkgname=cannonball
pkgver=0.34
pkgrel=2
pkgdesc='CannonBall: The Enhanced OutRun Engine'
arch=('i686' 'x86_64')
url="https://reassembler.blogspot.com"
license=('custom')
depends=('sdl' 'gcc-libs' 'sh')
makedepends=('cmake' 'boost')
install=$pkgname.install
source=($pkgname-$pkgver.tar.gz::"https://github.com/djyt/cannonball/archive/v$pkgver.tar.gz"
       "$pkgname.desktop"
       "$pkgname.sh"
	   fix-std-int16t.patch)
sha256sums=('e2cf8e21619b183a9fd835ae34ce65fb3d014c2fea37723fc8ba05681ed317ce'
            '04d0c0e9252bccfef97bb59c9e89376461f9b52845570b2ebc14610ce74cf1ff'
            '81f2a1a4e473c87272ce9321dfc616614760dc4c7a0d367d167413e3a71ec8b9'
            'ae08b3d3ed733e7d3e78ab5ae51d51e2cae3e7e88dd57c36737d6b5b48c04288')

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -i "$srcdir/fix-std-int16t.patch"
  rm -rf build
  mkdir build
}

build() {
  cd $pkgname-$pkgver/build
  cmake ../cmake \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
    -DTARGET=linux.cmake -DOpenGL_GL_PREFERENCE=GLVND -B .
  make
}

package() {
  cd $pkgname-$pkgver

  # xdg desktop, icon, launcher, binary
  install -Dm755 ../$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
  install -Dm644 res/icon.png "$pkgdir"/usr/share/icons/hicolor/256x256/apps/$pkgname.png
  install -Dm755 ../$pkgname.sh "$pkgdir"/usr/bin/$pkgname
  install -Dm755 build/$pkgname "$pkgdir"/usr/lib/$pkgname/$pkgname

  # widescreen tilemap data
  install -d "$pkgdir"/usr/share/${pkgname%-*}/res
  install -m644 res/*.bin "$pkgdir"/usr/share/${pkgname%-*}/res
  
  # configuration file
  install -Dm644 build/config.xml "$pkgdir"/usr/share/$pkgname/config.xml
  
  # doc + license
  install -Dm644 roms/roms.txt "$pkgdir"/usr/share/doc/$pkgname/roms.txt
  install -Dm644 docs/license.txt "$pkgdir"/usr/share/licenses/$pkgname/license.txt
}