blob: 607fff906250d5b1fe3e1ec278c91e6a7ea8d482 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
pkgname="caps-log"
pkgver=1.2.1
pkgrel=4
pkgdesc="A small, terminal-based journaling tool"
arch=('x86_64')
url="https://github.com/NikolaDucak/${pkgname}"
license=('MIT')
depends=('boost-libs' 'fmt>=9' 'gcc-libs' 'glibc' 'libgit2' 'openssl')
makedepends=('boost' 'cmake>=3.14' 'ftxui5') # 'gtest'
_pkgsrc="${pkgname}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz"
"${pkgname}_openssl_shared.patch")
# "${pkgname}_dont_install_tests.patch")
sha256sums=('10090ffc24ae28b7c466999d47c46c649daacbac86107d909d78bafef0e012d7'
'b86336c24292ecbf3a627129a0f6c416d121c16ea93ec5735d2a8049572de1e7')
prepare() {
cd "${srcdir}/${_pkgsrc}"
patch -Np1 -i "${srcdir}/${pkgname}_openssl_shared.patch"
# patch -Np1 -i "${srcdir}/${pkgname}_dont_install_tests.patch"
}
build() {
export CXXFLAGS+=" -I/usr/include/ftxui5"
export LDFLAGS+=" -L/usr/lib/ftxui5"
local cmake_options=(
-G 'Unix Makefiles' \
-B "${_pkgsrc}/build" \
-S "${_pkgsrc}" \
-DCMAKE_BUILD_TYPE:STRING='None' \
-DCMAKE_INSTALL_PREFIX:PATH='/usr' \
-Dftxui_DIR:PATH='/usr/lib/ftxui5/cmake/ftxui' \
-DCAPS_LOG_VERSION:STRING="${pkgver}" \
-DCAPS_LOG_BUILD_TESTS:BOOL=OFF \
-Wno-dev
)
cd "${srcdir}"
cmake "${cmake_options[@]}"
cmake --build "${_pkgsrc}/build"
}
# check() {
# local excluded_tests=""
# local ctest_flags=(
# --test-dir "${_pkgsrc}/build"
# --output-on-failure
# --parallel $(nproc)
# --exclude-regex "${excluded_tests}"
# )
#
# cd "${srcdir}"
# ctest "${ctest_flags[@]}"
# }
package() {
DESTDIR="${pkgdir}" cmake --install "${_pkgsrc}/build"
cd "${_pkgsrc}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENCE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|