PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: George Tsiamasiotis <gtsiam@windowslive.com>

pkgname=carburetor
pkgver=4.5.1
pkgrel=2
pkgdesc='Graphical settings app for tractor in GTK'
arch=(any)
url='https://framagit.org/tractor/carburetor'
license=('GPL-3.0-or-later')

depends=(
  python
  python-gobject
  gtk4
  libadwaita
  tractor
)
makedepends=(
  python-build
  python-setuptools
  python-installer
  python-wheel
)

source=("$pkgname-$pkgver.tar.gz::https://framagit.org/tractor/carburetor/-/archive/$pkgver/carburetor-$pkgver.tar.gz")
sha256sums=('138656a73c75e8619970a029112d2419168dbda4c112b33d356b0ecf11ab1d3e')

build() {
  cd "$pkgname-$pkgver"
  python -m build --wheel --no-isolation
}

package() {
  cd "$pkgname-$pkgver"

  # Install python package
  python -m installer --destdir="$pkgdir" dist/*.whl

  # Install man page
  install -Dm0644 -t "$pkgdir/usr/share/man/man1" \
    data/carburetor.1

  # Install desktop integration files
  install -Dm0644 -t "$pkgdir/usr/share/applications" \
    data/io.frama.tractor.carburetor.desktop
  install -Dm0644 -t "$pkgdir/usr/share/metainfo" \
    data/metainfo/io.frama.tractor.carburetor.metainfo.xml

  # Install icons
  mkdir -p "$pkgdir/usr/share/icons/hicolor"
  cp -dpr --no-preserve=ownership data/icons/* "$pkgdir/usr/share/icons/hicolor/"
}