blob: 3a366c1006a2d2f88d9d4180d2e4eb774bf4c846 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=cargo-compete
pkgver=0.10.6
pkgrel=1
pkgdesc="Cargo subcommand for competitive programming"
url="https://github.com/qryxip/cargo-compete"
depends=('gcc-libs' 'openssl' 'zlib')
makedepends=('cargo')
arch=('x86_64')
license=('Apache-2.0' 'MIT')
source=("${pkgname}-${pkgver}.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('6ea52a2fa24ca433307ea1d5224554ba8d07935c7857ab08536841b0466658d89bd6151829b1a65ef5b534a1e4a8ad08966c175316c4ffd0edaed36c51d8fcba')
options=('!lto')
prepare() {
cd "${pkgname}-${pkgver}"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${pkgname}-${pkgver}"
cargo build --release --frozen
}
check() {
cd "${pkgname}-${pkgver}"
cargo test --frozen
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm 755 "target/release/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
install -Dm 644 LICENSE-MIT -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim:set ts=2 sw=2 et:
|