blob: db1f052a07a41766c27cd5aa56094c391104ea9b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: djsigmann <aur+djsigmann@protonmail.com>
# shellcheck disable=SC2164
_pkgname=casual-pre-loader
pkgname="${_pkgname}-git"
pkgver=1.4.2.25.g0fd13a9
pkgrel=1
pkgdesc='TF2 particle modifications via some wizardry.'
arch=('x86_64')
url="https://github.com/cueki/${_pkgname}"
license=('GPL-3.0-or-later' 'CC-BY-NC-ND-4.0')
depends=('python>=3.11' 'python-pyqt6>=6.8.0' 'python-pillow>=11.1.0' 'python-pyxdg')
makedepends=('git' 'gendesk')
install="${_pkgname}.install"
source=("git+${url}")
sha256sums=('SKIP')
prepare() {
gendesk -n -f --pkgname "${_pkgname}" --pkgdesc "${pkgdesc}" --exec "${_pkgname}" --icon "${_pkgname}" --categories 'Utility' # generate desktop entry file
printf '%s\n' 'portable = False' >"${_pkgname}/core/are_we_portable.py" # notify the application that it cannot write to its own installation directory
}
pkgver() {
cd "${_pkgname}"
git describe --tag | sed 's/^v//; s/-/./g'
}
package() {
install -Dm644 "${_pkgname}.desktop" -t "${pkgdir}/usr/share/applications/" # desktop entry file
cd "${_pkgname}"
mkdir -p "${pkgdir}/usr"/{bin,share/pixmaps,"lib/${_pkgname}"}/ # pre-create dirs that we don't `install -D` into
# all other files and directories needed to run
cp -a \
main.py \
mods.zip \
mod_urls.json \
particle_system_map.json \
backup/ \
core/ \
gui/ \
operations/ \
quickprecache/ \
vtfedit/ \
"${pkgdir}/usr/lib/${_pkgname}/"
ln -s "/usr/lib/${_pkgname}/main.py" "${pkgdir}/usr/bin/${_pkgname}" # symlink the main.py file into the PATH as "${_pkgname}"
ln -s "/usr/lib/${_pkgname}/gui/cueki_icon.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png" # symlink the icon file into the correct location
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE" # license
install -Dm644 {README.md,READ_THIS.txt} -t "${pkgdir}/usr/share/doc/${_pkgname}/" # docs
}
|