blob: 2abc09685f05e4b2c67884b4211fefd1bc8a3e56 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Paul Hentschel (hpmachining)
# Contributor: greyltc
pkgname=cbang-git
pkgver=1.6.0.r134.g18f1e963
pkgrel=1
pkgdesc="A library of cross-platform C++ utilities"
arch=('x86_64')
url="https://github.com/CauldronDevelopmentLLC/cbang"
license=('LGPL2.1')
depends=(
'v8-r'
'libevent'
'sqlite'
're2'
'libyaml'
'zlib'
'bzip2'
'expat'
)
makedepends=(
'git'
'scons'
)
checkdepends=(
'python2'
)
optdepends=(
'mariadb-libs: MariaDB database support'
)
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
source=("git+https://github.com/CauldronDevelopmentLLC/cbang.git")
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
}
build() {
cd "${pkgname%-git}"
scons cxxstd="c++14" disable_local="libevent sqlite3 re2 libyaml zlib bzip2 expat"
}
check() {
cd "${pkgname%-git}/tests"
scons
python2 ./testHarness
}
package() {
cd "${pkgname%-git}"
scons install cxxstd="c++14" prefix="$pkgdir/opt/${pkgname%-git}"
install -m644 lib/libcbang.a -t "$pkgdir/opt/${pkgname%-git}/lib"
install -m644 lib/libcbang-boost.a -t "$pkgdir/opt/${pkgname%-git}/lib"
cp -a config/ "$pkgdir/opt/${pkgname%-git}/config/"
cp -a src/boost/boost/ "$pkgdir/opt/${pkgname%-git}/include/"
cp -a include/cbang/ "$pkgdir/opt/${pkgname%-git}/include/"
}
|