blob: 280ac96423adc716b56590e31c014b6095813b37 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Patrick Northon <northon_patrick3@yahoo.ca>
# Contributor: Felix Golatofski <contact@xdfr.de>
# Contributor: Nogweii <me@nogweii.net>
# Contributor: Marcin (CTRL) Wieczorek <marcin@marcin.co>
# Contributor: Xiao-Long Chen <chenxiaolong@cxl.epac.to>
pkgname=certmonger
pkgver=0.79.20
pkgrel=3
pkgdesc="Certificate status monitor and PKI enrollment client"
arch=(i686 x86_64)
url="https://pagure.io/${pkgname}"
license=('GPL-3.0-or-later')
depends=(nss tevent xmlrpc-c popt libdbus krb5 jansson systemd libidn2 nspr openssl talloc libxml2)
makedepends=(rpm-tools gettext)
checkdepends=(python-dbus diffutils dos2unix expect)
backup=(etc/${pkgname}/${pkgname}.conf)
install="${pkgname}.install"
source=("https://pagure.io/${pkgname}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('76685185172bbf2c766c477c399ce0b14c9fd2d81637b44b8da80ae045ebf6c650ae3d525a87dccd755a6c92d4a5916bb62f8ea1d8520c47ae64770be6a5d2be')
prepare() {
cd "${pkgname}-${pkgver}"
# Disable broken test.
sed -i '/028-dbus \\/d' 'tests/Makefile.am'
}
build() {
cd "${pkgname}-${pkgver}"
unset KRB5_CONFIG
autoreconf -i -f
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--sbindir=/usr/bin \
--libexecdir=/usr/lib/${pkgname} \
--localstatedir=/var \
--enable-systemd \
--enable-tmpfiles \
--with-tmpdir=/run/${pkgname} \
--with-homedir=/run/${pkgname} \
--with-uuid \
--with-gmp \
--with-xmlrpc \
--disable-dsa \
--enable-pie --enable-now
make
}
check() {
cd "${pkgname}-${pkgver}"
make check
}
package() {
cd "${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}/" install
}
|