summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0178ab57322f474baeac4cc1c782cac787789ad3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
# Maintainer: Shayne Hartford <shayneehartford@gmail.com>

pkgbase=chromeos-kde-git
pkgname=(chromeos-kde-git kvantum-theme-chromeos-git)
_pkgname=chromeos-kde
pkgver=r18.3fcbdb4
pkgrel=1
pkgdesc="ChromeOS theme for kde plasma"
arch=(any)
url="https://github.com/vinceliuice/$_pkgname"
license=('GPL3')
options=('!strip')
source=("git+$url.git")
sha256sums=('SKIP')
makedepends=('git')

pkgver() {
  cd "$srcdir/$_pkgname"
  
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package_chromeos-kde-git() {
    provides=('chromeos-kde')
    optdepends=('chromeos-gtk-theme: Matching GTK theme'
                'kvantum-theme-chromeos: ChromeOS theme for Kvantum Qt style (recommended)'
                'tela-icon-theme: Matching icon theme')

    cd $_pkgname

    install -d "$pkgdir"/usr/share
    
    rm sddm/{README.md,install.sh}
    
    # Temporary fix for upstream filestructure
    mv aurorae themes
    mkdir -p aurorae
    mv themes aurorae/
    
    mv sddm themes
    mkdir -p sddm
    mv themes sddm/

    cp -r aurorae "$pkgdir"/usr/share
    cp -r color-schemes "$pkgdir"/usr/share
    cp -r plasma "$pkgdir"/usr/share
    cp -r sddm "$pkgdir"/usr/share
}

package_kvantum-theme-chromeos-git() {
    provides=('kvantum-theme-chromeos')
    pkgdesc="ChromeOS theme for KDE Plasma 5"
    depends=(kvantum-qt5)

    cd $_pkgname

    install -d "$pkgdir"/usr/share

    cp -r Kvantum "$pkgdir"/usr/share
}