blob: 1f1a8d0286fb24cfb42b3ad4dbdadc8ad69703f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Doug Newgard <scimmia at archlinux dot org>
pkgname=chromium-widevine
pkgdesc='A browser plugin designed for the viewing of premium video content'
pkgver=4.10.2710.0
_chrome_ver=121.0.6167.184
pkgrel=1
epoch=1
arch=('x86_64')
url='https://www.widevine.com/'
license=('custom')
options=('!strip')
source=("https://dl.google.com/linux/deb/pool/main/g/google-chrome-stable/google-chrome-stable_${_chrome_ver}-1_amd64.deb")
sha256sums=('50380ed6c27b6e08054deec2dfa0a71d85e31bdaccf99a8508eccdc880e94346')
prepare() {
bsdtar -x --strip-components 4 -f data.tar.xz opt/google/chrome/WidevineCdm
}
pkgver() {
awk 'match($0,/"version": "([0-9.]*)"/,a) {print a[1];}' WidevineCdm/manifest.json
}
package() {
depends=('gcc-libs' 'glib2' 'glibc' 'nspr' 'nss')
install -dm755 "$pkgdir/usr/lib/chromium/"
cp -a WidevineCdm "$pkgdir/usr/lib/chromium/"
find "$pkgdir" -name '*.so' -exec chmod +x {} \;
install -Dm644 WidevineCdm/LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
# backward compatibility
ln -s WidevineCdm/_platform_specific/linux_x64/libwidevinecdm.so "$pkgdir/usr/lib/chromium/libwidevinecdm.so"
}
|