blob: 60383243fcc757ab1780deaf526adf31d2e3cfb0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: anenasa <anenasaa@yahoo.com>
# Contributor: Chih-Hsuan Yen <yan12125@gmail.com>
pkgname=chunghwa-post-webatm
epoch=1
pkgver=1.2508.12.1
pkgrel=1
pkgdesc='WebATM plugin for Chunghwa Post (中華郵政 WebATM 元件)'
arch=(any)
url='https://webatm.post.gov.tw/'
license=(unknown)
depends=(gnutls pcsclite sh wine)
makedepends=(msitools gendesk perl-image-exiftool p7zip imagemagick)
source=("ATMSetup-$pkgver.msi"::"https://webatm.post.gov.tw/postatm/cab/ATMSetup.msi"
"$pkgname")
sha256sums=('32f83b1c0830c492311f0cb6eb0f3b76db5f65496322f73c5560b750a47dfa4b'
'2a21dba5dea4132d3693cf3d6332cee2f3a0be650f0e19e76ece27cd834abb75')
prepare() {
msiextract ATMSetup-$pkgver.msi
}
pkgver() {
# Credit: https://askubuntu.com/a/717855
exiftool -ProductVersion ATMXHRService.exe | cut -f 2 -d : | sed 's# ##g'
}
build() {
7z x ATMXHRService.exe .rsrc
for icon in .rsrc/*/ICON/*.ico; do
dimension=$(identify -format "%wx%h" $icon)
mkdir -p icons/$dimension/apps
magick $icon icons/$dimension/apps/$pkgname.png
done
gendesk -n --pkgname "$pkgname" --name "Chunghwa Post WebATM" --categories "Office;Finance"
}
package() {
install -Dm755 $pkgname -t "$pkgdir"/usr/bin
install -Dm644 ATMXHRService.exe -t "$pkgdir"/usr/share/$pkgname
install -Dm644 cert.pem -t "$pkgdir"/usr/share/$pkgname
install -Dm644 prikey.pem -t "$pkgdir"/usr/share/$pkgname
install -Dm644 cacert.pem "$pkgdir"/usr/share/ca-certificates/trust-source/anchors/Chunghwa_Post_ATM.crt
install -Dm644 $pkgname.desktop -t "$pkgdir"/usr/share/applications
install -Ddm755 "$pkgdir"/usr/share/icons
cp -dr --no-preserve=ownership icons "$pkgdir"/usr/share/icons/hicolor
ln -s /usr/share/ca-certificates/trust-source/anchors/Chunghwa_Post_ATM.crt "$pkgdir"/usr/share/$pkgname/cacert.pem
}
|