blob: f560272ff80b0ad3bccf3930f2d94c4eacc55d8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Maintainer: Mikhail f. Shiryaev <mr dot felixoid at gmail dot com>
pkgname=clickhouse-lts
pkgver=24.8.6.70
pkgrel=1
pkgdesc='An open-source column-oriented database management system that allows generating analytical data reports in real time. LTS version'
arch=('x86_64' 'aarch64')
url='https://clickhouse.com'
license=('Apache')
depends=('tzdata' 'libcap')
provides=(clickhouse)
conflicts=(clickhouse)
_source_prefix='https://packages.clickhouse.com/deb/pool/main/c/clickhouse'
source_x86_64=(
"${_source_prefix}/clickhouse-client_${pkgver}_amd64.deb"
"${_source_prefix}/clickhouse-common-static_${pkgver}_amd64.deb"
"${_source_prefix}/clickhouse-server_${pkgver}_amd64.deb"
)
source_aarch64=(
"${_source_prefix}/clickhouse-client_${pkgver}_arm64.deb"
"${_source_prefix}/clickhouse-common-static_${pkgver}_arm64.deb"
"${_source_prefix}/clickhouse-server_${pkgver}_arm64.deb"
)
# for CARCH in x86_64 aarch64; do;
# pkgver=$(grep '^pkgver=' PKGBUILD | cut -f2 -d=);
# CARCH=$CARCH makepkg --verifysource --nobuild --noextract;
# done
# for CARCH in x86_64 aarch64; do;
# [ "$CARCH" == aarch64 ] && arch=arm64 || arch=amd64;
# echo "sha256sums_${CARCH}=("
# sha256sum clickhouse*"${pkgver}_${arch}.deb" | sed -r 's|(\w+).+| \1|';
# echo ')'
# done
sha256sums_x86_64=(
5a577b1e0afdddc39dfe039672be2449e4b9b69ea1155b64c93895c787582c43
072344a149663dc47480735b67a30981443e30056be0d35a3088926e8d6109bb
2257b3590e6ae0559f5dcf14369ed8b0c3187308a1c6914b03ec29c4ebccccb5
)
sha256sums_aarch64=(
e51806380ef0f87b171eae700c360df6f198553d239abd1c2ba809ba8ada572d
751fe38ce186299e9a791e479601f0923301d996a73def4cbda7232f4adfbe82
469c69083ae4f3ae02d6d491caa6d896f6499835f61e80e6268810462f70a770
)
_noextract_x86_64=(
clickhouse-client_"${pkgver}"_amd64.deb
clickhouse-common-static_"${pkgver}"_amd64.deb
clickhouse-server_"${pkgver}"_amd64.deb
)
_noextract_aarch64=(
clickhouse-client_"${pkgver}"_arm64.deb
clickhouse-common-static_"${pkgver}"_arm64.deb
clickhouse-server_"${pkgver}"_arm64.deb
)
noextract=(
"${_noextract_x86_64[@]}"
"${_noextract_aarch64[@]}"
)
install=$pkgname.install
backup=(
'etc/clickhouse-client/config.xml'
'etc/clickhouse-server/config.xml'
'etc/clickhouse-server/users.xml'
)
package() {
debs="_noextract_${CARCH}[@]"
for deb in "${!debs}"; do
bsdtar -xf "$deb"
tar xf data.tar.gz -C "${pkgdir}"
done
mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
mv "${pkgdir}/lib" "${pkgdir}/usr/lib"
mv "${pkgdir}/usr/share/doc/clickhouse-server/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/"
rm -rf "${pkgdir}/etc/cron.d" \
"${pkgdir}/etc/init.d" \
"${pkgdir}/etc/security" \
"${pkgdir}/etc/systemd" \
"${pkgdir}/usr/share/doc"
}
# vim:set ts=2 sw=2 et:
|