summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 316f7a4e9485dc4b71aaa8103fba22a04b7886f5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: George Angelopoulos <george@usermod.net>

pkgname=collectl
pkgver=4.3.1
pkgrel=1
pkgdesc="A tool for viewing and gethering system performance metrics."
arch=('any')
url="http://collectl.sourceforge.net/"
license=('GPL2' 'custom:artistic')
depends=('perl')
backup=('etc/collectl.conf')
source=("https://sourceforge.net/projects/collectl/files/collectl/${pkgname}-${pkgver}/${pkgname}-${pkgver}.src.tar.gz")
md5sums=('92ac8c3fb99132df7111306c4360301b')

package() {
	cd "${pkgname}-${pkgver}"
    DESTDIR="${pkgdir}" ./INSTALL

    # systemd service file exists upstream but is not handled quite well by
    # the upstream INSTALL script. We install it here explicitly.
    install -D -m644 service/${pkgname}.service "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"

    # we don't have sysv init in arch
    rm -rf ${pkgdir}/etc/init.d

    # uninstall script is not needed since we're using a package manager :)
    rm -rf ${pkgdir}/usr/share/${pkgname}/UNINSTALL

    # collectl is licensed under the GPL2 and some version of the ARTISTIC
    # license. Since the version of the license from upstream doesn't
    # match with any of the common ones in Arch Linux, we'll copy the
    # artistic license here as custom.
    install -D -m644 ARTISTIC "${pkgdir}/usr/share/licenses/${pkgname}/ARTISTIC"
}