summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 420091d1885019e1b2d4f46c2978d747ffca0366 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
# Former maintainer: John Jenkins <twodopeshaggy@gmail.com>
# Contributor: Mateusz Loskot <mateusz@loskot.net>

pkgname=colormake-git
pkgver=0.9.20140503.r19.g93dd19b
pkgrel=1
pkgdesc="Colorize the output of make"
arch=('any')
url="http://bre.klaki.net/programs/colormake/"
license=('GPL2')
depends=('perl' 'bash')
makedepends=('git')
provides=('colormake')
conflicts=('colormake')
source=("git+https://github.com/pagekite/Colormake.git")
sha256sums=('SKIP')


prepare() {
  cd "Colormake"

  # adjust scripts to colormake.pl path
  sed -i 's#colormake.pl#/usr/share/colormake/colormake.pl#g' "colormake"
}

pkgver() {
  cd "Colormake"

  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
  cd "Colormake"

  # executables
  install -dm755 "$pkgdir/usr/bin"
  cp -r {clmake,clmake-short,colormake,colormake-short} "$pkgdir/usr/bin"

  install -Dm755 "colormake.pl" "$pkgdir/usr/share/colormake/colormake.pl"

  # man page
  install -Dm644 "colormake.1" "$pkgdir/usr/share/man/man1/colormake.1"

  # documentation
  install -dm755 "$pkgdir/usr/share/doc/colormake"
  install -m644 \
    AUTHORS \
    BUGS \
    ChangeLog \
    README.md \
    "$pkgdir/usr/share/doc/colormake"
}