blob: f65b3a9d4b34d384653245b7584debb636cbe35d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Vitalii Kuzhdin <vitaliikuzhdin@gmail.com>
# Contributor: benbusby <contact at benbusby dot com>
pkgname="colorstorm"
pkgver=3.0.0
pkgrel=1
pkgdesc="An interactive TUI for creating color themes for Vim, VSCode, and Sublime"
arch=(
'aarch64'
'armv7h'
'x86_64'
)
url="https://github.com/benbusby/${pkgname}"
license=(
'MIT'
)
depends=(
'glibc'
)
makedepends=(
'go'
)
_pkgsrc="${url##*/}-${pkgver}"
source=(
"${_pkgsrc}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
)
sha256sums=('49cd30ad2d0680f9f027633fafb691730fce21a9ab337cc9407e0186d00d8964')
prepare() {
export GOMODCACHE="${srcdir}/go-mod-cache"
cd "${srcdir}/${_pkgsrc}"
go mod download -modcacherw -x
go mod verify
mkdir -p "build"
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOCACHE="${srcdir}/go-cache"
export GOMODCACHE="${srcdir}/go-mod-cache"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${_pkgsrc}"
go build -v -o "build/${pkgname}" .
}
check() {
cd "${srcdir}/${_pkgsrc}"
go test ./...
}
package() {
cd "${srcdir}/${_pkgsrc}"
install -vDm755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|