blob: e34caa5459da4e994e007af84cd822d7053fd9e2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Torsten Keßler <tpkessler at archlinux dot org>
# Contributor: acxz <akashpatel2008 at yahoo dot com>
pkgname=comgr
pkgdesc='Compiler support library for ROCm LLVM'
pkgver=5.4.1
pkgrel=1
arch=('x86_64')
url='https://github.com/RadeonOpenCompute/ROCm-CompilerSupport'
license=('custom:NCSAOSL')
depends=('rocm-device-libs')
makedepends=('rocm-cmake' 'rocm-llvm')
source=("${pkgname}-${pkgver}.tar.gz::$url/archive/rocm-$pkgver.tar.gz")
sha256sums=('a46ad7a53034417615d4cf9375909400dbe7198ea8076b524c22e2653728c06b')
_dirname="$(basename "$url")-$(basename "${source[0]}" .tar.gz)"
build() {
cmake \
-Wno-dev \
-S "$_dirname/lib/comgr" \
-B build \
-DCMAKE_INSTALL_PREFIX=/opt/rocm \
-DCMAKE_BUILD_TYPE=None \
-DBUILD_TESTING=ON \
-DCMAKE_PREFIX_PATH=/opt/rocm/llvm
cmake --build build
}
check() {
cmake --build build --target check-comgr
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dm644 "$_dirname/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|