blob: e7db575e48d143a4737489d699de567f237b891b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Adam Perkowski <adas1per@protonmail.com>
# https://github.com/adamperkowski/PKGBUILDs
pkgname=connet
pkgver=0.5.0
pkgrel=1
pkgdesc='A P2P reverse proxy with NAT traversal'
arch=('x86_64' 'aarch64')
url="https://github.com/$pkgname-dev/$pkgname"
license=('Apache-2.0')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('895aa21fc5ff6cad77608e4e390a12b2f33f989e864bbb91a45833b67120bd41')
makedepends=('go')
depends=('glibc')
prepare() {
cd "$pkgname-$pkgver"
mkdir -p build
}
build() {
cd "$pkgname-$pkgver"
if [ "$CARCH" = 'x86_64' ]; then
export GOARCH=amd64
elif [ "$CARCH" = 'aarch64' ]; then
export GOARCH=arm64
fi
export GOOS=linux
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOPATH="$srcdir"
export GOFLAGS='-buildmode=pie -mod=readonly -modcacherw'
go build -o "build/$pkgname" "cmd/$pkgname/main.go"
}
check() {
cd "$pkgname-$pkgver"
go test -cover -timeout 10s ./...
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 "build/$pkgname" -t "$pkgdir/usr/bin"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
}
# vim: ts=2 sw=2 et:
|