PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=cosmic-ext-applet-emoji-selector-git
pkgver=0.1.5.r43.g4530c2d
pkgrel=1
pkgdesc="Emoji Selector for COSMIC™️ DE"
arch=('x86_64')
url="https://github.com/bGVia3VjaGVu/cosmic-ext-applet-emoji-selector"
license=('MPL-2.0 AND MIT')
depends=(
  'cosmic-applets'
  'noto-fonts-emoji'
)
makedepends=(
  'cargo'
  'git'
  'just'
)
provides=("${pkgname%-git}")
conflicts=(
  "${pkgname%-git}"
  'cosmic-applet-emoji-selector-git'
  'emoji-selector-applet-for-cosmic-git'
)
source=('git+https://github.com/bGVia3VjaGVu/cosmic-ext-applet-emoji-selector.git')
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname%-git}"
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${pkgname%-git}"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "${pkgname%-git}"
  export RUSTUP_TOOLCHAIN=stable
  just build-release
}

package() {
  cd "${pkgname%-git}"
  just rootdir="$pkgdir" install

  install -Dm644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname/"
}