PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48


# Maintainer: yuhldr <yuhldr@gmail.com>
pkgname=cosmic-ext-applet-minimon-git
_pkgname=minimon-applet
pkgver=0.6.0.r3.g78d77c3
pkgrel=1
pkgdesc="A COSMIC applet for displaying CPU/Memory/Network/Disk/GPU usage in the Panel or Dock.."
arch=('x86_64')
url="https://github.com/cosmic-utils/${_pkgname}"
license=('GPL-3.0')
depends=(
	'cosmic-applets'
	'libxkbcommon'
)
makedepends=(
    'cargo'
    'git'
    'just'
)
provides=(${_pkgname})
conflicts=("${pkgname%-git}" "minimon-applet-for-cosmic")
source=("git+https://github.com/cosmic-utils/${_pkgname}.git")
sha256sums=('SKIP')

pkgver() {
    cd ${_pkgname}
    git describe --long --tags --abbrev=7 | sed 's/^v//;s/^epoch-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd ${_pkgname}

    export RUSTUP_TOOLCHAIN=stable
    cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
    cd ${_pkgname}
    export RUSTUP_TOOLCHAIN=stable
    just build-release
}

package() {
    cd ${_pkgname}
    just rootdir="$pkgdir" install

    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}