PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Maintainer: Posi <posi1981@gmail.com>

# Contributor: Bruce Zhang
pkgname=cpod
_name=CPod
_nodeversion=8.16.1
pkgver=1.28.2
pkgrel=1
pkgdesc="A simple, beautiful podcast app for Windows, macOS, and Linux."
arch=('x86_64' 'i686')
url="https://github.com/z-------------/CPod"
license=('Apache-2.0')
depends=('electron2')
makedepends=('yarn' 'jq' 'moreutils' 'nvm' 'gulp' 'python2')
provides=('cpod')
conflicts=('cpod-bin' 'cpod-git')
source=("$pkgname-$pkgver.src.tar.gz::https://github.com/z-------------/$_name/archive/v$pkgver.tar.gz")
sha256sums=('aac8f4d5ba63a45141442c265252e52a65906eca8d2e449f859dd8dadf390485')

prepare() {
	cd "$_name-$pkgver"
    electronVersion=$(tail -1 /usr/lib/electron2/version)
    sed -i "s|\"electron\": \".*|\"electron\": \"$electronVersion\",|" package.json
	source /usr/share/nvm/init-nvm.sh
	nvm install "$_nodeversion"
	nvm use "$_nodeversion"
	yarn
}

build() {
	cd "$_name-$pkgver"
	gulp
	yarn run pack
	source /usr/share/nvm/init-nvm.sh
	nvm deactivate
	nvm uninstall "$_nodeversion"
}

package() {
	cd "$srcdir/$_name-$pkgver/dist/linux-unpacked/resources"
	install -Dm644 app.asar "$pkgdir/usr/share/cpod/app.asar"

	cd "$srcdir/$_name-$pkgver/build/icons"
	for file in *x*.png; do
		install -Dm644 "$file" "$pkgdir/usr/share/icons/hicolor/${file%.png}/apps/cpod.png"
	done
	cd "$srcdir/$_name-$pkgver/build"
	install -Dm644 icon.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/cpod.svg"

	echo "#!/bin/env sh
exec electron2 /usr/share/cpod/app.asar \$@" > "$srcdir/cpod.sh"
	install -Dm755 "$srcdir/cpod.sh" "$pkgdir/usr/bin/cpod"

	echo "[Desktop Entry]
Name=CPod
Comment=A simple, beautiful podcast app.
Exec=/usr/bin/cpod %U
Terminal=false
Type=Application
Icon=cpod
Categories=Audio;AudioVideo;" > "$srcdir/cpod.desktop"
	install -Dm644 "$srcdir/cpod.desktop" "$pkgdir/usr/share/applications/cpod.desktop"
}