PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

# Maintainer:  Marcell Meszaros < marcell.meszaros AT runbox.eu >
# Contributor: UnicornDarkness (AUR user)
# PKGBUILD based on original AUR/cpu-x: https://aur.archlinux.org/packages/cpu-x

_realname=CPU-X
_basename=cpu-x
pkgname="${_basename}-opencl"
pkgver=5.0.4
pkgrel=1
pkgdesc='Gathers information on CPU, motherboard, GPU and more (with OpenCL support)'
arch=('i686' 'x86_64')
url="https://thetumultuousunicornofdarkness.github.io/${_realname}"
_repourl="https://github.com/TheTumultuousUnicornOfDarkness/${_realname}"
license=('GPL3')
depends=(
  'dconf'
  'glfw'
  'gtk3'
  'gtkmm3'
  'hicolor-icon-theme'
  'libcpuid>=0.6.0'
  'libgl'
  'ncurses'
  'opencl-icd-loader'
  'pciutils'
  'procps-ng>=4.0.0'
  'vulkan-icd-loader'
)
makedepends=(
  'cmake'
  'nasm'
  'ninja'
  'opencl-headers>=2:2023.02.06'
  'vulkan-headers'
)
optdepends=(
  'opencl-driver: packaged OpenCL driver'
  'opengl-driver: packaged OpenGL driver'
  'vulkan-driver: packaged Vulkan driver'
)
provides=("${_basename}=${pkgver}")
conflicts=("${_basename}")
_tarname="${_basename}-${pkgver}"
source=("${_tarname}.tar.gz::${_repourl}/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('134f8a8fe6782279f7288d891a66b3d426b0e173de3d5445367c94029aa9d33348d037f5bca25690aff16f00d261777a71de6847991e564578099b03ff398453')

prepare() {
  cmake -S "${_realname}-${pkgver}" -B build \
    -GNinja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBEXECDIR='lib/cpu-x' \
    -DWITH_GTK=ON \
    -DWITH_NCURSES=ON \
    -DWITH_GETTEXT=ON \
    -DWITH_LIBCPUID=ON \
    -DWITH_LIBPCI=ON \
    -DWITH_LIBGLFW=ON \
    -DWITH_VULKAN=ON \
    -DWITH_OPENCL=ON \
    -DWITH_LIBPROCPS=ON \
    -DWITH_LIBSTATGRAB=OFF \
    -DWITH_DMIDECODE=ON \
    -DWITH_BANDWIDTH=ON \
    -DFORCE_LIBSTATGRAB=OFF
}

build() {
  cmake --build build
}

check() {
  ninja -C build test
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
}