blob: 1ef1a7b8f9e8a2f144e5771c6e36a180b8097c5e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Gallifreyan <gallifreyan@protonmai.ch>
# Contributor: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Ícar N. S. <icar.nin@protonmail.com>
pkgname=crawley
pkgver=1.7.5
pkgrel=2
pkgdesc="Simple web scraper"
arch=('x86_64')
url="https://github.com/s0rg/${pkgname}"
license=(MIT)
depends=(glibc)
provides=(crawley)
conflicts=("crawley-bin" "crawley-git")
makedepends=(go)
source=(${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha512sums=('c309bc8a0787f58662bf222660387e698061082bd31be4198c42a7e21e98b3e8dca9c8f852398c4e775a4c857847282ac170ca775d66e02c830a02d3fb59571a')
prepare() {
cd ${pkgname}-${pkgver}
mkdir -p build
go mod download
}
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
cd ${pkgname}-${pkgver}
go vet ./...
go build -o build -ldflags="-linkmode=external -X main.gitVersion=${pkgver}" ./cmd/crawley
}
check() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd ${pkgname}-${pkgver}
go test ./...
}
package() {
cd ${pkgname}-${pkgver}
install -Dv "build/${pkgname}" -t "${pkgdir}/usr/bin/"
install -Dvm644 LICENSE -t "$pkgdir/usr/share/licenses/${pkgname}"
install -Dvm644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}
|