PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=cs-signal-git
pkgver=1.3.0.r0.g727df0a
pkgrel=1
pkgdesc='Library for thread aware signal/slot delivery (git version)'
arch=('x86_64')
url='https://www.copperspice.com/'
license=('BSD')
depends=('gcc-libs')
makedepends=('git' 'cmake' 'catch2' 'cs-libguarded')
provides=('cs-signal')
conflicts=('cs-signal')
source=('git+https://github.com/copperspice/cs_signal.git')
sha256sums=('SKIP')

pkgver() {
    git -C cs_signal describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^signal\.//;s/^v//'
}

build() {
    cmake -B build -S cs_signal \
        -DCMAKE_BUILD_TYPE:STRING='None' \
        -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
        -DBUILD_TESTS:BOOL='ON' \
        -Wno-dev
    make -C build
}

check() {
    make -C build test
}

package() {
    DESTDIR="$pkgdir" cmake --install build
    install -D -m644 cs_signal/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}