summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1d4147006b482184dbab18d5b5603ecbadee9dfe (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer: Ivan Puntiy <ivan.puntiy at gmail>
# Contributor: <francois.archlinux.org>

pkgname=culmus
pkgver=0.133
pkgrel=1
pkgdesc="A collection of Type1 and TrueType Hebrew fonts"
arch=('any')
url="http://culmus.sourceforge.net"
license=('GPL2')
depends=('fontconfig' 'xorg-fonts-alias' 'xorg-font-utils' 'xorg-fonts-encodings')
source=(
  "http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz"
  "${pkgname}-0.121-fontconfig_fix.patch"
)
sha256sums=('c0c6873742d07544f6bacf2ad52eb9cb392974d56427938dc1dfbc8399c64d05'
            '6ba13854700bd9cdf6b8facd920082aed367bedabe10e93bd39cfe6bf8eb76fd')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # fix due to fontconfig 2.10.1 update - patch mailed to upstream
  patch culmus.conf "${srcdir}/${pkgname}-0.121-fontconfig_fix.patch"
}

package() {
  # install Type1 fonts
  install -m755 -d "${pkgdir}/usr/share/fonts/Type1"
  install -m644 "${srcdir}/culmus-${pkgver}/"*.{afm,pfa} \
    "${pkgdir}/usr/share/fonts/Type1"

  # install ttf fonts
  install -m755 -d "${pkgdir}/usr/share/fonts/TTF"
  install -m644 "${srcdir}/culmus-${pkgver}/"*.ttf \
    "${pkgdir}/usr/share/fonts/TTF"

  # install otf fonts
  install -m755 -d "${pkgdir}/usr/share/fonts/OTF"
  install -m644 "${srcdir}/culmus-${pkgver}/"*.otf \
    "${pkgdir}/usr/share/fonts/OTF"

  # install provided config file with priority 61
  install -m755 -d "${pkgdir}/etc/fonts/conf.avail/"
  install -m644 "${srcdir}/culmus-${pkgver}/culmus.conf" \
    "${pkgdir}/etc/fonts/conf.avail/61-culmus.conf"

  # symlink for the abovementioned config file
  install -m755 -d "${pkgdir}/etc/fonts/conf.d"
  ln -fs "../conf.avail/61-culmus.conf" "${pkgdir}/etc/fonts/conf.d/"
}