blob: 31beb640823d85d10a850350404197c3638fd8b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Maintainer on AUR: Whyme Lyu <callme5long@gmail.com>
#
# Imported from Arch official repo:
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
_proj=curl
pkgname=curl-c-ares
pkgver=8.7.1
_git_tag="curl-${pkgver//./_}"
pkgrel=2
pkgdesc='command line tool and library for transferring data with URLs (built with c-ares)'
arch=('x86_64')
url='https://curl.se/'
license=('MIT')
depends=('ca-certificates'
'brotli' 'libbrotlidec.so'
'c-ares' 'libcares.so'
'krb5' 'libgssapi_krb5.so'
'libidn2' 'libidn2.so'
'libnghttp2' 'libnghttp2.so'
'libnghttp3' 'libnghttp3.so'
'libpsl' 'libpsl.so'
'libssh2' 'libssh2.so'
'openssl' 'libcrypto.so' 'libssl.so'
'zlib' 'libz.so'
'zstd' 'libzstd.so')
makedepends=('git')
checkdepends=('valgrind')
provides=('curl' 'libcurl.so')
conflicts=('curl')
validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
source=("git+https://github.com/curl/${_proj}.git#tag=${_git_tag}?signed")
sha512sums=('SKIP')
prepare() {
cd $_proj
# no '-DEV' in version, release date from tagged commit...
sed -i \
-e "/\WLIBCURL_VERSION\W/c #define LIBCURL_VERSION \"${pkgver}\"" \
-e "/\WLIBCURL_TIMESTAMP\W/c #define LIBCURL_TIMESTAMP \"$(git log -1 --format=%cs "$_git_tag")\"" \
include/curl/curlver.h
autoreconf -fi
}
build() {
local _configure_options=(
--prefix='/usr'
--mandir='/usr/share/man'
--disable-ldap
--disable-ldaps
--disable-manual
--enable-ares
--enable-ipv6
--with-gssapi
--with-libssh2
--with-random='/dev/urandom'
--with-ca-bundle='/etc/ssl/certs/ca-certificates.crt'
)
mkdir build-curl
cd "${srcdir}"/build-curl
"${srcdir}/$_proj/configure" \
"${_configure_options[@]}" \
--enable-versioned-symbols \
--with-fish-functions-dir=/usr/share/fish/vendor_completions.d/ \
--with-openssl \
--with-openssl-quic \
--with-zsh-functions-dir=/usr/share/zsh/site-functions/
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd build-curl
# disable test 433, since it requires the glibc debug info
make TFLAGS="-v -a -k -p -j$(nproc) !433" test-nonflaky
}
package() {
cd build-curl
make DESTDIR="${pkgdir}" install
make DESTDIR="${pkgdir}" install -C scripts
cd "${srcdir}/${_proj}"
# license
install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m0644 COPYING
}
|