summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: f4df24ce645cc75e773c385cdd0ea288022c0d57 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: PumpkinCheshire <sollyonzou@gmail.com>

pkgname=dain-ncnn-vulkan-git
pkgver=20210210.r0.gf29cb02
pkgrel=2
pkgdesc="DAIN, Depth-Aware Video Frame Interpolation implemented with ncnn library"
arch=('x86_64')
url="https://github.com/nihui/dain-ncnn-vulkan"
license=('MIT')
depends=('vulkan-icd-loader' 'libwebp')
makedepends=('git' 'cmake' 'glslang-git' 'vulkan-headers' 'vulkan-icd-loader' 'ncnn' 'libwebp')
provides=("dain-ncnn-vulkan")
conflicts=("dain-ncnn-vulkan" "dain-ncnn-vulkan-bin")
source=('git+https://github.com/nihui/dain-ncnn-vulkan.git')
md5sums=('SKIP')

pkgver() {
    git -C ${pkgname%-git} describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    sed -i 's|path_t model = PATHSTR("best")|path_t model = PATHSTR("/usr/share/dain-ncnn-vulkan/best/")|' "${pkgname%-git}"/src/main.cpp

    sed -i 's|return get_executable_directory() + path;|return "/usr/share/dain-ncnn-vulkan/" + path;|' "${pkgname%-git}"/src/filesystem_utils.h
}

build() {
    cmake -B build -S "${pkgname%-git}"/src \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DGLSLANG_TARGET_DIR=/usr/lib/cmake \
        -DUSE_SYSTEM_NCNN=on \
        -DUSE_SYSTEM_WEBP=on
    cmake --build build
}

package() {
    install -Dm755 -t "${pkgdir}/usr/bin" build/${pkgname%-git}
    install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" ${pkgname%-git}/LICENSE

    cd "${srcdir}/${pkgname%-git}/models/"
    for f in best/*; do
        install -Dm 644 "$f" ${pkgdir}/usr/share/${pkgname%-git}/"$f"
    done
}