blob: 391ec6f61e0858c6e68b819cea6ec5a3bf2cd2a6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: DCMfx <https://dcmfx.github.io>
pkgname=dcmfx
pkgver=0.27.0
pkgrel=1
pkgdesc='CLI tool for working with DICOM and DICOM JSON'
arch=('x86_64' 'aarch64')
url="https://dcmfx.github.io"
license=('AGPL-3.0-or-later')
source=("$pkgname-$pkgver.tar.gz::https://github.com/dcmfx/dcmfx/archive/v$pkgver.tar.gz")
sha256sums=('0e6b586eeef1178cbf0d6f01e58b6d780d772dffeddc90eb1cd8770385199a02')
makedepends=('cargo' 'clang' 'cmake' 'nasm')
depends=('ffmpeg' 'gcc-libs' 'glibc')
options=('!lto')
prepare() {
cd "$pkgname-$pkgver/src/rust"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "$pkgname-$pkgver/src/rust"
cargo build --release --frozen --bin dcmfx_cli
}
check() {
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cd "$pkgname-$pkgver/src/rust"
cargo test --release --frozen
}
package() {
cd "$pkgname-$pkgver/src/rust"
install -Dm755 "target/release/dcmfx_cli" "$pkgdir/usr/bin/dcmfx"
}
# vim: ts=2 sw=2 et:
|