summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c8ca4a27367bf748b66c6149ad73785b5e5150d3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Deposite Pirate <dpirate at metalpunks dot info>
#
# Upstream: https://git.metalpunks.info/arch-ports

_pkgname=deadbeef-fb
pkgname=deadbeef-plugin-fb-gtk3-git
pkgver=r166.g355e614
pkgrel=1
pkgdesc="A filebrowser plugin for the DeaDBeeF audio player"
arch=('i686' 'x86_64')
url="https://gitlab.com/zykure/deadbeef-fb"
license=('GPL2')
depends=('deadbeef-git' 'gtk3')
makedepends=('git' 'autoconf' 'automake' 'libtool')
source=("${_pkgname}::git+https://gitlab.com/zykure/${_pkgname}")
sha256sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  printf "r%s.g%s" \
    "$(git rev-list --count HEAD)" \
    "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${_pkgname}"
  ./autogen.sh
}

build() {
  cd "${_pkgname}"
  CFLAGS="${CFLAGS}" ./configure --prefix=/usr --disable-gtk2
  make
}

package() {
  cd "${_pkgname}"
  make DESTDIR="${pkgdir}" install
  rm \
    "${pkgdir}/usr/share/doc/deadbeef-fb/LICENSE" \
    "${pkgdir}/usr/share/doc/deadbeef-fb/version"
}