blob: fb9b6e20aca13fc5b5fc6b5cebac73e5bc31d7d3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Maintainer: dreieck
# Contributor: maz-1
_pkgname=deadbeef-qt5
pkgname=${_pkgname}-git
epoch=1
pkgver=r76.20210729.04b1404
pkgrel=2
pkgdesc="Qt based user interface plugin for DeaDBeeF music player."
arch=(
'i686'
'x86_64'
)
url='https://github.com/maz-1/deadbeef-qt'
license=('GPL2')
depends=(
'qt5-base'
'deadbeef'
)
makedepends=(
'cmake'
'git'
'qt5-tools'
)
provides=(
"${_pkgname}"
"deadbeef-qt"
"deadbeef-qt-git"
)
conflicts=(
"${_pkgname}"
'deadbeef-qt'
'deadbeef-qt-git'
)
install='deadbeef-qt5-git.install'
source=(
"${_pkgname}::git+https://github.com/maz-1/${_pkgname}.git"
"${install}"
)
sha256sums=(
'SKIP'
'5aeda9c427f33182f7fb172a2707eae2b0a32d71efef04879622686a05e9e377'
)
pkgver() {
cd "${srcdir}/${_pkgname}"
_rev="$(git rev-list --count HEAD)"
_date="$(git log -1 --date=format:"%Y%m%d" --format="%ad")"
_hash="$(git rev-parse --short HEAD)"
if [ -z "${_rev}" ]; then
error "git commit count could not be determined."
return 1
else
printf '%s' "r${_rev}.${_date}.${_hash}"
fi
}
build() {
mkdir -p "${srcdir}/build"
cd "${srcdir}/build"
cmake \
-DARTWORK_ENABLED=YES \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DHOTKEYS_ENABLED=YES \
"../${_pkgname}"
make
}
package() {
cd "${srcdir}/build"
make DESTDIR="${pkgdir}" install
for _srcdocfile in README.md; do
install -D -v -m644 "${srcdir}/${_pkgname}/${_srcdocfile}" "${pkgdir}/usr/share/doc/${_pkgname}/${_srcdocfile}"
done
}
|