PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: justforlxz <justforlxz@gmail.com>

pkgname=deepin-polkit-agent-ext-gnomekeyring-git
pkgver=5.0.11.r0.gdf093ef
pkgrel=1
pkgdesc="GNOME keyring extension for dde-polkit-agent"
arch=('x86_64' 'aarch64')
url="https://github.com/linuxdeepin/dpa-ext-gnomekeyring"
license=('GPL3')
depends=('deepin-polkit-agent-git' 'libgnome-keyring')
makedepends=('git' 'cmake' 'ninja' 'qt5-tools' 'libgnome-keyring' 'deepin-polkit-agent-git')
conflicts=('deepin-polkit-agent-ext-gnomekeyring')
provides=('deepin-polkit-agent-ext-gnomekeyring')
groups=('deepin-git')
source=("$pkgname::git+https://github.com/linuxdeepin/dpa-ext-gnomekeyring/")
sha512sums=('SKIP')

pkgver() {
    cd $pkgname
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd $pkgname
    if [[ ! -z ${sha} ]];then
      git checkout -b $sha
    fi
}

build() {
  cd $pkgname

  cmake . -G Ninja -DCMAKE_INSTALL_PREFIX=/usr
  ninja
}

package() {
  cd $pkgname
  DESTDIR="$pkgdir" ninja install
}