PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=demoiccmax-git
pkgver=r344.gdc78afc
pkgrel=1
pkgdesc="Demonstration Implementation for iccMAX color profiles"
arch=('i686' 'x86_64')
url="https://www.color.org/iccmax.xalter"
license=('LicenseRef-demoiccmax')
depends=('gcc-libs' 'libtiff' 'libxml2')
makedepends=('git' 'cmake' 'nlohmann-json')
provides=("demoiccmax=$pkgver")
conflicts=('demoiccmax')
options=('staticlibs')
source=("git+https://github.com/InternationalColorConsortium/DemoIccMAX.git")
sha256sums=('SKIP')


pkgver() {
  cd "DemoIccMAX"

  _rev=$(git rev-list --count --all)
  _hash=$(git rev-parse --short HEAD)
  printf "r%s.g%s" "$_rev" "$_hash"
}

build() {
  cd "DemoIccMAX"

  CFLAGS="$CFLAGS -ffat-lto-objects" \
  CXXFLAGS="$CXXFLAGS -ffat-lto-objects" \
  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    -DUSE_SYSTEM_LIBXML2=ON \
    Build/Cmake
  cmake --build "_build"
}

check() {
  cd "DemoIccMAX"

  #cmake --build "_build" --target test
}

package() {
  cd "DemoIccMAX"

  DESTDIR="$pkgdir" cmake --install "_build"
  install -Dm644 "LICENSE.md" -t "$pkgdir/usr/share/licenses/demoiccmax"
}