blob: 999f2f47250fd4aaa0f878181c4a3087603fd15a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Contributor: Aaron Lindsay <aaron@aaronlindsay.com>
pkgname=devkitppc-portlibs-mxml
pkgver=2.6
pkgrel=4
pkgdesc='Small XML parser library (for Nintendo Gamecube/Wii/Wii U homebrew development)'
arch=('any')
url='http://www.minixml.org/'
license=('LGPL')
options=(!strip libtool staticlibs)
depends=('devkitppc')
source=("http://downloads.sourceforge.net/sourceforge/devkitpro/mxml-$pkgver-src.tar.bz2")
sha256sums=('780d4bc7c3b5ab207412487402cc56dff670521da8a57315ca0047c2d4667ad5')
build() {
cd mxml-$pkgver
# set environment
source /etc/profile.d/devkitppc.sh
export CFLAGS="-g -O2 -ffunction-sections -fdata-sections"
./configure --prefix="$DEVKITPRO/portlibs/ppc" --host=powerpc-eabi \
--disable-shared --enable-static
make
}
package() {
cd mxml-$pkgver
make DSTROOT="$pkgdir" install
# remove useless stuff
rm -r "$pkgdir"/opt/devkitpro/portlibs/ppc/{share,bin}
}
|