blob: ad7c676d5a7f375b9aede4f3ad7203aaddcd540e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Mufeed Ali <lastweakness@tuta.io>
pkgname=dialect
pkgver=2.3.0
pkgrel=1
pkgdesc="A translation app for GNOME."
arch=('any')
url="https://apps.gnome.org/Dialect"
license=('GPL-3.0-or-later')
depends=('dbus-python' 'gst-python' 'libadwaita' 'libsoup3' 'python-gobject' 'python-gtts')
makedepends=('blueprint-compiler' 'git' 'gobject-introspection' 'meson')
checkdepends=('appstream-glib')
_commit=db9d47f0253a327fe2208ccf563a1a1ddd2cc806 # tags/2.3.0^0
source=("git+https://github.com/dialect-app/dialect.git#commit=$_commit"
'git+https://github.com/dialect-app/po.git')
sha256sums=('da2f83db0e9ff2687600cdfd4b1b0930e0f406fce85b9dec3232f216bc3e8db3'
'SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd "$pkgname"
git submodule init
git config submodule.po.url "$srcdir/po"
git -c protocol.file.allow=always submodule update
}
build() {
arch-meson "$pkgname" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
meson install -C build --destdir "$pkgdir"
}
|