blob: a3db60ab3d90e34b7a63d231242541fc48f91c15 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Tim Schumacher <timschumi@gmx.de>
# Contributor: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Morgan <morganamilo@archlinux.org>
pkgname=discord-ptb
_pkgname=DiscordPTB
pkgver=0.0.118
pkgrel=1
pkgdesc="All-in-one voice and text chat for gamers - public test build"
arch=('x86_64')
url='https://discordapp.com'
license=('custom')
options=(!strip)
depends=('libnotify' 'libxss' 'nspr' 'nss' 'gtk3')
optdepends=('libpulse: Pulseaudio support'
'xdg-utils: Open files'
'noto-fonts-cjk: Font for special characters such as /shrug face'
'emoji-font: Fonts for emoji support')
source=("https://dl-ptb.discordapp.net/apps/linux/$pkgver/$pkgname-$pkgver.tar.gz"
'LICENSE.html::https://discordapp.com/terms'
'OSS-LICENSES.html::https://discordapp.com/licenses')
sha512sums=('a35ac767e7aa5d8508904f71887b8393e622e1d414335122a38c8bac75049423cd64380786539deb28b44c62c9590e445d5f70732fdef59e475fa2cac0756c5c'
'SKIP'
'SKIP')
prepare() {
cd $_pkgname
sed -i "s|Exec=.*|Exec=/usr/bin/$pkgname|" $pkgname.desktop
echo 'Path=/usr/bin' >> $pkgname.desktop
}
package() {
install -d "$pkgdir"/opt/$pkgname
cp -a $_pkgname/. "$pkgdir"/opt/$pkgname
chmod 755 "$pkgdir"/opt/$pkgname/$_pkgname
rm "$pkgdir"/opt/$pkgname/postinst.sh
install -d "$pkgdir"/usr/{bin,share/{pixmaps,applications}}
ln -s /opt/$pkgname/$_pkgname "$pkgdir"/usr/bin/$pkgname
ln -s /opt/$pkgname/discord.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
ln -s /opt/$pkgname/$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
# setuid on chrome-sandbox
chmod u+s "$pkgdir"/opt/$pkgname/chrome-sandbox
install -Dm644 LICENSE.html "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.html
install -Dm644 OSS-LICENSES.html "$pkgdir"/usr/share/licenses/$pkgname/OSS-LICENSES.html
}
|