blob: b278f094011643a7abd3718bd005d0a49a891193 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Dmytro Meleshko <dmytro dot meleshko at gmail dot com>
_pkgname=docs-gl
pkgname="${_pkgname}-git"
pkgver=r337.7842647
pkgrel=1
pkgdesc="An improved version of the official OpenGL documentation"
arch=(any)
url="https://docs.gl/"
license=('custom')
depends=()
makedepends=('git' 'python')
options=(!strip)
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("${pkgname}::git+https://github.com/BSVino/docs.gl.git"
"${pkgname}-jquery-bonsai::git+https://github.com/BSVino/jquery-bonsai.git"
"${pkgname}-jquery-cookie::git+https://github.com/carhartl/jquery-cookie.git"
"${pkgname}-htmlmin::git+https://github.com/mankyd/htmlmin.git"
"${pkgname}.patch")
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'9fb6a78bc04c481417d9ad93d1841c1522b1e67d89fa58a4b76f4d14ef6236f1')
pkgver() {
cd "${srcdir}/${pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${pkgname}"
git submodule init
git config submodule.'html/copy/jquery-bonsai'.url "${srcdir}/${pkgname}-jquery-bonsai"
git config submodule.'html/copy/jquery-cookie'.url "${srcdir}/${pkgname}-jquery-cookie"
git config submodule.'htmlmin'.url "${srcdir}/${pkgname}-htmlmin"
git submodule update
git apply "${srcdir}/${pkgname}.patch"
}
build() {
cd "${srcdir}/${pkgname}"
python compile.py --local-assets
}
package() {
cd "${srcdir}/${pkgname}"
mkdir -p "${pkgdir}/usr/share/doc"
cp -r "htdocs" "${pkgdir}/usr/share/doc/${_pkgname}"
}
|