blob: 89fb1545e552e05b2508bd8c96c2414e2def0d5f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# Maintainer: pyamsoft <pyam(dot)soft(at)gmail(dot)com>
# Please read the comments in the PKGBUILD if you wish to attempt to use
# multiple versions of the dolphin emulator.
#
# Installing multiple versions alongside each other is not tested too often,
# use at own risk. Please report build issues.
pkgname=dolphin-emu-faster-melee
# shellcheck disable=SC2034
pkgver=4.4
# shellcheck disable=SC2034
pkgrel=1
# shellcheck disable=SC2034
pkgdesc='The FasterMelee NetPlay build of the Dolphin Emulator'
# shellcheck disable=SC2034
arch=('x86_64')
# shellcheck disable=SC2034
url='http://fastermelee.net'
# shellcheck disable=SC2034
license=('GPL')
# shellcheck disable=SC2034
install="faster-melee.install"
# shellcheck disable=SC2034
makedepends=('cmake')
# shellcheck disable=SC2034
depends=('bluez-libs' 'enet' 'ffmpeg' 'libao' 'libevdev' 'mbedtls' 'miniupnpc'
'portaudio' 'sfml' 'soundtouch' 'xdg-utils' 'wxgtk')
# shellcheck disable=SC2034
optdepends=('pulseaudio: PulseAudio backend')
# shellcheck disable=SC2034
options=('!emptydirs')
# The commit for FasterMelee 4.3 (unchanged for FasterMelee 4.4)
# shellcheck disable=SC2034
source=("${pkgname}::git+https://github.com/Tinob/Ishiiruka.git#commit=0b00f1f6267190a8bf9a3584497a35d8762eb0a9"
"GALE01r2.ini"
"GALE01.ini"
"MNCE02.ini"
"NMNB01.ini"
"PALE02.ini"
)
# shellcheck disable=SC2034
sha256sums=('SKIP'
'eae12be9d008453d09bf1379315a2299eca9c76cc093727f8f41926193981c50'
'a930e0490bfa95f66f96919d320e04f99d6988587209700a536bf7549d53466a'
'4dd62a40be7a41c92079c9ee23f5fd458c85f275431881c707450f634fdcf24c'
'4dd62a40be7a41c92079c9ee23f5fd458c85f275431881c707450f634fdcf24c'
'4dd62a40be7a41c92079c9ee23f5fd458c85f275431881c707450f634fdcf24c')
# shellcheck disable=SC2034
provides=('dolphin-emu')
build() {
# shellcheck disable=SC2154
cd "${srcdir}/${pkgname}" || {
msg "Failed to cd into ${srcdir}/${pkgname}"
return 1
}
mkdir build
cd build || {
msg "Failed to cd into ${srcdir}/${pkgname}/build"
return 1
}
# To install multiple versions of the Dolphin emulator, use
#
# -DCMAKE_INSTALL_PREFIX='/opt/dolphin-emu-faster-melee'
#
# instead of
#
# -DCMAKE_INSTALL_PREFIX='/usr'
cmake .. \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DCMAKE_CXX_FLAGS='-fno-pie' \
-DENABLE_LTO='TRUE' \
-DUSE_SHARED_ENET='TRUE' \
-DDISTRIBUTOR='aur.archlinux.org'
make
}
package() {
cd "${srcdir}/${pkgname}" || {
msg "Failed to cd into ${srcdir}/${pkgname}"
return 1
}
cd build || {
msg "Failed to cd into ${srcdir}/${pkgname}/build"
return 1
}
# shellcheck disable=SC2154
make DESTDIR="${pkgdir}" install
# To install multiple versions of the Dolphin emulator,
# install the repository dolphin-emu first as it includes this file.
# Then comment out this line.
install -Dm 644 ../Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
# Patch Gecko Codes
#
# To install multiple versions of the Dolphin emulator, use
#
# cp -f "${srcdir}/GALE01r2.ini" "${pkgdir}"/opt/dolphin-emu-faster-melee/dolphin-emu/sys/GameSettings/GALE01r2.ini
#
# Instead of the line below
cp -f "${srcdir}/GALE01r2.ini" "${pkgdir}"/usr/share/dolphin-emu/sys/GameSettings/GALE01r2.ini
}
# vim: ts=2 sw=2 et:
|