blob: 1c8dda49fd4fd09e46c88ae0026e88b1521d2246 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Contributor: Balló György <ballogyor+arch at gmail dot com>
pkgname=dooble
pkgver=2022.04.04
pkgrel=1
pkgdesc="Web browser based on QtWebEngine"
arch=(x86_64)
url="https://textbrowser.github.io/dooble/"
license=('BSD')
depends=('qt5-webengine')
source=("$pkgname-$pkgver.tar.gz::https://github.com/textbrowser/$pkgname/archive/$pkgver.tar.gz")
sha256sums=('9dd4be621f50e7401533dce25a9697f2f59f64b019d907a2ed999c57cad41657')
prepare() {
cd $pkgname-$pkgver
sed -i 's|Categories=Web|Categories=Network;Qt;WebBrowser;|
s|Exec=.*|Exec=dooble|
s|Icon=.*|Icon=dooble|' dooble.desktop
sed -i 's|QString path(QDir::currentPath());|QString path("/usr/share/dooble");|' Source/dooble_settings.cc
}
build() {
cd $pkgname-$pkgver
qmake dooble.pro
make
}
package() {
cd $pkgname-$pkgver
install -Dm755 Dooble "$pkgdir/usr/bin/dooble"
install -Dm644 Icons/Logo/dooble.png "$pkgdir/usr/share/pixmaps/dooble.png"
install -Dm644 dooble.desktop "$pkgdir/usr/share/applications/dooble.desktop"
install -Dm644 -t "$pkgdir/usr/share/dooble/Translations" Translations/dooble_*.qm
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/dooble/LICENSE"
}
|