blob: 042a61bda9d980f59009955ffbfc99ac63b819b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id$
# Contributor: Balló György <ballogyor+arch at gmail dot com>
pkgname=dooble
pkgver=2.1.6
pkgrel=1
pkgdesc="Colorful Web browser"
arch=(x86_64)
url="https://textbrowser.github.io/dooble/"
license=('BSD')
depends=('qt5-webengine')
source=("$pkgname-$pkgver.tar.gz::https://github.com/textbrowser/$pkgname/archive/$pkgver.tar.gz")
sha256sums=('35b3e12763e9f7350efd2d91b312f5511eff62e76a015ad46ae9cb4a07ea92d8')
prepare() {
cd $pkgname-$pkgver/2.x
sed -i '/QMAKE_LFLAGS_RELEASE += -Wl,-rpath/d' dooble.pro
sed -i 's|Exec=.*|Exec=dooble|
s|Icon=.*|Icon=dooble|' dooble.desktop
sed -i 's|QString path(QDir::currentPath());|QString path("/usr/share/dooble");|' Source/dooble_settings.cc
}
build() {
cd $pkgname-$pkgver/2.x
qmake
make
}
package() {
cd $pkgname-$pkgver/2.x
install -Dm755 Dooble "$pkgdir/usr/bin/dooble"
install -Dm644 Icons/Logo/dooble.png "$pkgdir/usr/share/pixmaps/dooble.png"
install -Dm644 dooble.desktop "$pkgdir/usr/share/applications/dooble.desktop"
install -Dm644 -t "$pkgdir/usr/share/dooble/Translations" Translations/dooble_*.qm
install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/dooble/LICENSE"
}
|