PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Larry Oates <leafman12345@gmail.com>
pkgname=doomfire-wallpaper
pkgver=1.4.0
pkgrel=1
pkgdesc="Animated doom fire effect wallpaper for Wayland compositors"
arch=('x86_64')
url="https://github.com/larry-oates/doomfire-wallpaper"
license=('0BSD')
depends=()
makedepends=('git' 'cargo')
optdepends=('grim: for the screen_burn feature')
provides=('doomfire-wallpaper')
conflicts=('doomfire-wallpaper')
source=("$pkgname::git+https://github.com/larry-oates/doomfire-wallpaper#tag=v${pkgver}")
md5sums=('SKIP')

prepare() {
  cd "$srcdir/$pkgname"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
  cd "$srcdir/$pkgname"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --release --locked --frozen
}

package() {
  cd "$srcdir/$pkgname"
  install -Dm755 "target/release/doomfire-wallpaper" "$pkgdir/usr/bin/doomfire-wallpaper"
  install -Dm644 "README.md" "$pkgdir/usr/share/doc/doomfire-wallpaper/README.md"
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}