blob: 7b2e8dc215b2b3bd82a81e6231518787ddcb078c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
# Maintainer: Attila Greguss <floyd0122[at]gmail[dot]com>
# armv7h and aarch64 Comaintainers needed
pkgbase=dotnet-core-8.0-bin
pkgname=(
'aspnet-runtime-8.0-bin'
'dotnet-runtime-8.0-bin'
'dotnet-sdk-8.0-bin'
'dotnet-targeting-pack-8.0-bin'
'aspnet-targeting-pack-8.0-bin'
)
pkgver=8.0.31.sdk425
_runtimever=8.0.31
_sdkver=8.0.425
pkgrel=1
arch=('x86_64' 'armv7h' 'aarch64')
url='https://www.microsoft.com/net/core'
license=('MIT')
options=('staticlibs')
source_armv7h=("https://builds.dotnet.microsoft.com/dotnet/Sdk/${_sdkver}/dotnet-sdk-${_sdkver}-linux-arm.tar.gz")
source_aarch64=("https://builds.dotnet.microsoft.com/dotnet/Sdk/${_sdkver}/dotnet-sdk-${_sdkver}-linux-arm64.tar.gz")
source_x86_64=("https://builds.dotnet.microsoft.com/dotnet/Sdk/${_sdkver}/dotnet-sdk-${_sdkver}-linux-x64.tar.gz")
sha512sums_armv7h=('9fa85240f5487d2aafe18bcf454ccec924534a454c46136dcafcd810d3e4ca009e234ae8926617c4ffee48e98bf388ef25bbee45706ac5ce897cf11e7d14d914')
sha512sums_aarch64=('84a4d017d74d7aa842e981679d1b044e6be1f35b9b2b214021e30bc40871d016d29611cca373d8502ad5c890e3ad360ee698f9cf2d7a4d5a9fba102d88ba310f')
sha512sums_x86_64=('934b8060a7190e5909ad1fd0785db542f487b3bbf6cdd14826b02095fdd0d0394298b1634085eff302928fccc33f7c1a7253e9b87df555fc36fce819bcd2e798')
package_dotnet-runtime-8.0-bin() {
pkgdesc='The .NET Core runtime (binary)'
depends=(
"dotnet-host>=${_runtimever}"
'libgcc'
'libstdc++'
'glibc'
'icu'
'libunwind'
'zlib'
'openssl'
)
optdepends=('lttng-ust: CoreCLR tracing')
provides=("dotnet-runtime=${_runtimever}" "dotnet-runtime-8.0")
conflicts=("dotnet-runtime=${_runtimever}" "dotnet-runtime-8.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet/shared,licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.NETCore.App "${pkgdir}"/usr/share/dotnet/shared/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-runtime-8.0-bin
}
package_aspnet-runtime-8.0-bin() {
pkgdesc='The ASP.NET Core runtime (binary)'
depends=('dotnet-runtime-8.0-bin')
provides=("aspnet-runtime=${_runtimever}" "aspnet-runtime-8.0")
conflicts=("aspnet-runtime=${_runtimever}" "aspnet-runtime-8.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet/shared,licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.AspNetCore.App "${pkgdir}"/usr/share/dotnet/shared/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/aspnet-runtime-8.0-bin
}
package_dotnet-sdk-8.0-bin() {
pkgdesc='The .NET Core SDK (binary)'
depends=(
'glibc'
'libgcc'
'libstdc++'
'dotnet-runtime-8.0-bin'
'dotnet-targeting-pack-8.0-bin'
'netstandard-targeting-pack')
optdepends=('aspnet-targeting-pack-bin: Build ASP.NET Core applications')
provides=("dotnet-sdk=${pkgver}" "dotnet-sdk-8.0")
conflicts=("dotnet-sdk=${pkgver}" "dotnet-sdk-8.0")
install -dm 755 "${pkgdir}"/usr/share/{dotnet,licenses}
cp -dr --no-preserve='ownership' sdk sdk-manifests templates "${pkgdir}"/usr/share/dotnet/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-sdk-8.0-bin
}
package_dotnet-targeting-pack-8.0-bin() {
pkgdesc='The .NET Core targeting pack (binary)'
depends=(
'netstandard-targeting-pack'
)
provides=(dotnet-targeting-pack=${_runtimever} dotnet-targeting-pack-8.0)
conflicts=(dotnet-targeting-pack=${_runtimever} dotnet-targeting-pack-8.0)
if [ $CARCH = 'x86_64' ]; then msarch=x64;
elif [ $CARCH = 'armv7h' ]; then msarch=arm;
elif [ $CARCH = 'aarch64' ]; then msarch=arm64; fi
install -dm 755 "${pkgdir}"/usr/share/{dotnet,dotnet/packs,licenses}
cp -dr --no-preserve='ownership' packs/Microsoft.NETCore.App.{Host.linux-${msarch},Ref} "${pkgdir}"/usr/share/dotnet/packs/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/dotnet-targeting-pack-8.0-bin
}
package_aspnet-targeting-pack-8.0-bin() {
pkgdesc='The ASP.NET Core targeting pack (binary)'
depends=(
'dotnet-targeting-pack-8.0-bin'
)
provides=(aspnet-targeting-pack=${_runtimever} aspnet-targeting-pack-8.0)
conflicts=(aspnet-targeting-pack=${_runtimever} aspnet-targeting-pack-8.0)
install -dm 755 "${pkgdir}"/usr/share/{dotnet,dotnet/packs,licenses}
cp -dr --no-preserve='ownership' packs/Microsoft.AspNetCore.App.Ref "${pkgdir}"/usr/share/dotnet/packs/
ln -s dotnet-host-bin "${pkgdir}"/usr/share/licenses/aspnet-targeting-pack-8.0-bin
}
|