blob: 1e0b862512b1cf0952edf8f6551bcc93012f7e01 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Florian Maunier <fmauneko@dissidence.ovh>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Max Liebkies <mail@maxliebkies.de>
pkgbase=dotnet-core-preview
pkgname=('dotnet-host-preview' 'dotnet-runtime-preview' 'aspnet-runtime-preview' 'dotnet-sdk-preview')
pkgver=5.0.0+100+preview.4.20258.7
pkgrel=1
arch=('x86_64' 'armv7h' 'aarch64')
url='https://www.microsoft.com/net/core'
license=('MIT')
makedepends=(
'clang' 'cmake' 'curl' 'git' 'icu' 'krb5' 'libunwind' 'lldb' 'llvm'
'lttng-ust' 'openssl' 'zlib'
)
options=('staticlibs')
source=(
'dotnet.sh'
)
source_x86_64=(
'https://download.visualstudio.microsoft.com/download/pr/473651e3-55d5-4e7c-b255-2cbe11358eea/6b6f33d86ee00720b36a7c34200f4d0c/dotnet-sdk-5.0.100-preview.4.20258.7-linux-x64.tar.gz'
)
source_armv7h=(
'https://download.visualstudio.microsoft.com/download/pr/76bea762-22d3-4ce8-a3cf-64276d4b9aca/74a7bed0b9e67a11cf025115c52506ca/dotnet-sdk-5.0.100-preview.4.20258.7-linux-arm.tar.gz'
)
source_aarch64=(
'https://download.visualstudio.microsoft.com/download/pr/adb3ed49-26af-40a2-8df3-1460b178e55e/01187433dc24decf562d90d4bb2ce058/dotnet-sdk-5.0.100-preview.4.20258.7-linux-arm64.tar.gz'
)
sha256sums=('4978b3a31a94032b425d2a2a9b5a17f506f36fb784fbfefdf2cfea9485a30f47')
sha256sums_x86_64=('2a3481f958c8891e29075807d6f982dc2beedce67512431d8c1fd0f5092bf047')
sha256sums_armv7h=('55ab6df9ca407b00cc3b9354f428a47818affa5f185252ea365724b740fd0471')
sha256sums_aarch64=('0ac538203de1bfd096abfb771e6eb3ff7bcf8b2b08a15c5a19de802724225401')
package_dotnet-host-preview() {
pkgdesc='A generic driver for the .NET Core Command Line Interface (preview)'
provides=("dotnet-host=${pkgver%+*}")
conflicts=('dotnet-host')
install -dm 755 "${pkgdir}"/{opt/dotnet,usr/share/licenses/dotnet-host-preview}
cp -dr --no-preserve='ownership' dotnet host "${pkgdir}"/opt/dotnet/
cp -dr --no-preserve='ownership' LICENSE.txt ThirdPartyNotices.txt "${pkgdir}"/usr/share/licenses/dotnet-host-preview
install -Dm 755 "${srcdir}"/dotnet.sh "${pkgdir}"/usr/bin/dotnet
}
package_dotnet-runtime-preview() {
pkgdesc='The .NET Core runtime (preview)'
depends=('dotnet-host-preview' 'icu' 'krb5' 'libunwind' 'openssl' 'zlib'
'libcurl.so')
optdepends=('lttng-ust: CoreCLR tracing')
provides=("dotnet-runtime=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet/shared,usr/share/licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.NETCore.App "${pkgdir}"/opt/dotnet/shared/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/dotnet-runtime-preview
}
package_aspnet-runtime-preview() {
pkgdesc='The ASP.NET Core runtime (preview)'
depends=('dotnet-runtime-preview')
provides=("aspnet-runtime=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet/shared,usr/share/licenses}
cp -dr --no-preserve='ownership' shared/Microsoft.AspNetCore.App "${pkgdir}"/opt/dotnet/shared/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/aspnet-runtime-preview
}
package_dotnet-sdk-preview() {
pkgdesc='The .NET Core SDK (preview)'
depends=('dotnet-runtime-preview')
provides=("dotnet-sdk=${pkgver%+*}")
install -dm 755 "${pkgdir}"/{opt/dotnet,usr/share/licenses}
cp -dr --no-preserve='ownership' packs sdk templates "${pkgdir}"/opt/dotnet/
ln -s dotnet-host-preview "${pkgdir}"/usr/share/licenses/dotnet-sdk-preview
}
# vim: ts=2 sw=2 et:
|